Changing Fields

Minimize(A): GalRep -> GalRep

To: GalRep                    Default: 

Replace Group(A) by its smallest possible quotient through which all components of \(A\) factor. If To is specified, instead replace Group(A) by Group(To), assuming the \(A\) factors through it.

Example: Galrep Minimize (ex-b8e822)

We take an extension \(F\) of \(K={\mathbb{Q}}_3\) with Galois group \(F_5=C_5:C_4\) of order 20. It has five irreducible representations. Four of them are 1-dimensional, and so they actually factor through a smaller Galois group (\(C_1\), \(C_2\) or \(C_4\)). Minimize descends them to these Galois groups, although they are of course still the same as representations of the absolute Galois group.

> K:=pAdicField(3,20);
> R<x>:=PolynomialRing(K);
> list:=GaloisRepresentations(x^5-3);
> list;
[
1-dim trivial Galois representation 1 over Q3[20],
1-dim unramified Galois representation (1,1,-1,-1,1) with G=F5, I=C5
   over Q3[20],
1-dim unramified Galois representation (1,-1,-zeta(4)_4,zeta(4)_4,1)
   with G=F5, I=C5 over Q3[20],
1-dim unramified Galois representation (1,-1,zeta(4)_4,-zeta(4)_4,1)
   with G=F5, I=C5 over Q3[20],
4-dim Galois representation (4,0,0,0,-1) with G=F5, I=C5, conductor 3^4
   over Q3[20]
]
> [Minimize(A): A in list];
[
1-dim trivial Galois representation 1 over Q3[20],
1-dim unramified Galois representation (1,-1) with G=C2, I=C1 over Q3[20],
1-dim unramified Galois representation (1,-1,-zeta(4)_4,zeta(4)_4)
   with G=C4, I=C1 over Q3[20],
1-dim unramified Galois representation (1,-1,zeta(4)_4,-zeta(4)_4)
   with G=C4, I=C1 over Q3[20],
4-dim Galois representation (4,0,0,0,-1) with G=F5, I=C5, conductor 3^4
   over Q3[20]
]
> forall{A: A in list | A eq Minimize(A)};
true

Run in calculatorCopy input

Finally, we illustrate how the parameter To may be used to descend a Galois representation to a specific Galois group, in this case the Galois group \(\mathop{\rm Gal}\nolimits(F/K)\cong C_4\) of the degree 4 unramified extension of \(K\).

> F:=ext<K|4>;                    // Take F = degree 4 unr. ext. of K, and
> B:=PermutationCharacter(F,K);   // any B with BaseField(B)=K, Field(B)=F
> list[2];
1-dim unramified Galois representation (1,1,-1,-1,1) with G=F5, I=C5 over Q3[20]
> Minimize(list[2]: To:=B);
1-dim unramified Galois representation (1,1,-1,-1) with G=C4, I=C1 over Q3[20]
> Minimize(list[2]);
1-dim unramified Galois representation (1,-1) with G=C2, I=C1 over Q3[20]

Run in calculatorCopy input

Restriction(A, L): GalRep, FldPad -> GalRep

BaseChange(A, L): GalRep, FldPad -> GalRep

Base change (restriction) of a Galois representation \(A\) over \(K\) over a finite extension \(L/K\).

Example: Galrep Basechange (ex-3dc7d9)

We take a 2-dimensional irreducible representation of \(\mathop{\rm Gal}\nolimits({\mathbb{Q}}_2(\zeta_3,\root 3 \of 2))\cong S_3\) and check that its base change to \({\mathbb{Q}}_2(\zeta_3)\) is reducible.

> K:=pAdicField(2,20);
> R<x>:=PolynomialRing(K);
> A:=GaloisRepresentations(x^3-2)[3]; A;
2-dim Galois representation (2,0,-1) with G=S3, I=C3, conductor 2^2 over Q2[20]
> L:=ext<K|2>;
> R:=Restriction(A,L); R;
2-dim Galois representation (2,-1,-1) with G=C3, I=C3, conductor 2^2
   over ext<Q2[20]|2>
> IsIrreducible(A),IsIrreducible(R);
true false

Run in calculatorCopy input

Induction(A, K0): GalRep, FldPad -> GalRep

Induction of a Galois representation \(A\) over \(K\) to a subfield \(K_0\subset K\).

Example: Galrep Induction (ex-aae099)

> K0:=pAdicField(2,20);     // K0=Q2
> K:=ext<K0|2>;             // K=Q2(zeta_3)
> R<x>:=PolynomialRing(K);
> A:=GaloisRepresentations(x^3-102)[3];
> A;                        // 1-dim character over K
1-dim Galois representation (1,-zeta(3)_3-1,zeta(3)_3) with G=C3, I=C3,
   conductor 2^1 over ext<Q2[20]|2>
> Induction(A,K0);          // Induced to K0
2-dim Galois representation (2,0,-1) with G=S3, I=C3, conductor 2^2 over Q2[20]

Run in calculatorCopy input