Advanced Examples

Example: Local and Global Epsilon Factors for Dirichlet Characters

Example: Galrep Funeq (ex-938a3a)

We illustrate the relation between local and global epsilon-factors for Dirichlet characters (or Artin representations). Pick any Dirichlet character \(\chi\); in this example we take the unique odd one of conductor \(5\cdot 19\), order 6 and Im\(\,\chi(2)>0\).

> D:=FullDirichletGroup(5*19);
> L:=[chi: chi in Elements(D) | (Order(chi) eq 6) and
>   (Conductor(chi) eq 5*19) and IsOdd(chi) and (Imaginary(chi(2)) ge 0)];
> assert #L eq 1;
> chi:=L[1];

Run in calculatorCopy input

We compute its local Galois representations at all the bad places: 5, 19 and \(\infty\). (See §Hodge Structure for Hodge structures at \(\infty\).)

> G5:=GaloisRepresentation(chi,5); G5;
1-dim Galois representation (1,-1,-zeta(3)_3-1,zeta(3)_3,zeta(3)_3+1,-zeta(3)_3)
   with G=C6, I=C2, conductor 5^1 over Q5[40]
> G19:=GaloisRepresentation(chi,19); G19;
1-dim Galois representation (1,-1,zeta(3)_3,-zeta(3)_3-1,zeta(3)_3+1,-zeta(3)_3)
   with G=C6, I=C6, conductor 19^1 over Q19[40]
> Ginfty:=HodgeStructure(ArtinRepresentation(chi)); Ginfty;
Hodge structure of weight 0 given by <0,0,1>

Run in calculatorCopy input

Now compute the corresponding local root numbers - the way the conventions are set up for Artin representations, at \(\infty\) it is the root number of the Hodge structure that enters the functional equation.

> localrootno:=[ComplexField()| RootNumber(G5),RootNumber(G19),
>               RootNumber(Ginfty)];
> globalrootno:=&*localrootno;

Run in calculatorCopy input

The global root number is the sign of the L-series of \(\chi\), and we check that it agrees with the one determined numerically from the functional equation:

> L:=LSeries(chi);
> ok:=CheckFunctionalEquation(L);
> Sign(L);
0.910747215816471738723996800097 + 0.412964294924567358770699943664*I
> globalrootno;
0.910747215816471738723996800108 + 0.412964294924567358770699943647*I

Run in calculatorCopy input

Example: Reconstructing a Galois Representation from its Euler Factors

Example: Galrep Reconstruction (ex-6f8047)

Every semisimple Galois representation \(A\) over a \(p\)-adic field \(K\) can be uniquely recovered from its Euler factors over the extensions of \(K\) ([Dokchitser and Dokchitser, 2015, Thm. 1]). We illustrate this with a Galois representation attached to an elliptic curve

\[E/K: y^2 = x^3-26x, \qquad K={\mathbb{Q}}_{13}.\]

> K:=pAdicField(13,20);
> E:=EllipticCurve([K|-26,0]);
> A:=GaloisRepresentation(E);
> Degree(A),IsSemisimple(A);
2 true

Run in calculatorCopy input

Without looking at \(A\), let us reconstruct it from its Euler factors over extensions of \(K\). First we determine the inertia group InertiaGroup(A) by looking for a field over which \(A\) is unramified (i.e. \(E\) has good reduction). As the residue characteristic is \(>3\), one of the fields \({\mathbb{Q}}_{13}(\root d\of{13})\) will do, for \(d=1,2,3,4\) or 6.

> R<x>:=PolynomialRing(K);
> [EulerFactor(BaseChange(A,ext<K|x^d-13>)): d in [1,2,3,4,6]];
[ 1, 1, 1, 13*x^2 + 4*x + 1, 1 ]

Run in calculatorCopy input

We see that the representation becomes unramified over \(L={\mathbb{Q}}_{13}(\root 4\of{13})\), a cyclic extension of degree 4, but not over its subfields. So the inertia group must be \(C_4\),

\[{\rm InertiaGroup}(A) \,\,\cong\,\, I_{L/K} \,\,=\,\, \mathop{\rm Gal}\nolimits(L/K) \,\,\cong\,\, C_4.\]

Over \(L\) the representation \(U=\mathop{\rm Res}\nolimits_{L} A\) is unramified, and there it is determined by its Euler factor. It is a sum of two unramified characters, \(\mathop{\rm Frob}\nolimits_{L}^{-1}\mapsto -2\pm 3i\).

> L:=ext<K|x^4-13>;
> f1:=EulerFactor(BaseChange(A,L));
> U:=UnramifiedRepresentation(L,f1); U;
2-dim unramified Galois representation Unr(1+4*x+13*x^2) over
   ext<Q13[20]|x^4-13>
> Decomposition(U);
[
1-dim unramified Galois representation Unr(-2+3*i) over ext<Q13[20]|x^4-13>,
1-dim unramified Galois representation Unr(-2-3*i) over ext<Q13[20]|x^4-13>
]

Run in calculatorCopy input

We are ready to reconstruct \(A\). Its restriction to inertia is a faithful 2-dimensional representation of \(C_4\), of determinant 1 (as it comes from an elliptic curve), so it must be \(\sigma\oplus\sigma^{-1}\) where \(\sigma\) is one of the faithful 1-dimensional characters of \(C_4\).

> GroupName(InertiaGroup(A)),IsUnramified(Determinant(A));  // just checking
C4 true
> list:=GaloisRepresentations(x^4-13);
> sigma:=[g: g in list | Order(Character(g)) eq 4][1];
> sigma;
1-dim Galois representation (1,-1,zeta(4)_4,-zeta(4)_4) with G=C4, I=C4,
   conductor 13^1 over Q13[20]

Run in calculatorCopy input

Since \(\mathop{\rm Frob}\nolimits_K=\mathop{\rm Frob}\nolimits_L\) commutes with inertia in the Galois group

\[\mathop{\rm Gal}\nolimits(K^{nr}(\root 4 \of{13})/K) \cong\mathop{\rm Gal}\nolimits(K^{nr}/K) \times \mathop{\rm Gal}\nolimits(L/K) \cong\hat{\mathbb{Z}}\times C_4\]

through which \(A\) factors, \(A(\mathop{\rm Frob}\nolimits_K)\) and \(A(\sigma)\) are simultaneously diagonalizable in \(\mathop{\rm GL}\nolimits_2({\mathbb{C}})\), so \(A\) must be one of the following two representations \(A_1\) and \(A_2\):

> Qi<i>:=CyclotomicField(4);
> A1 := sigma * UnramifiedCharacter(K,-2-3*i) +
>       sigma^(-1)*UnramifiedCharacter(K,-2+3*i);
> A2 := sigma * UnramifiedCharacter(K,-2+3*i) +
>       sigma^(-1)*UnramifiedCharacter(K,-2-3*i);

Run in calculatorCopy input

Finally, to determine which one it is, we pick another extension of \(K\) where \(A\) becomes unramified and compare the Euler factors. Then we see that \(A\) must be \(A_2\).

> L2:=ext<K|x^4-26>;
> EulerFactor(BaseChange(A,L2));
13*x^2 - 6*x + 1
> EulerFactor(BaseChange(A1,L2));
13*x^2 + 6*x + 1
> EulerFactor(BaseChange(A2,L2));
13*x^2 - 6*x + 1
> A eq A2;
true

Run in calculatorCopy input