---
title: "Clifford Algebra Structure"
canonical: "https://docs.magma-maths.org/v2.30-1/Algebras/CliffordAlgebras/operations.html"
source: "https://docs.magma-maths.org/v2.30-1/Algebras/CliffordAlgebras/operations.md"
part: "Algebras"
chapter: "Clifford Algebras"
breadcrumbs:
  - {"title": "Magma Handbook", "source": "https://docs.magma-maths.org/v2.30-1/index.md"}
  - {"title": "Algebras", "source": "https://docs.magma-maths.org/v2.30-1/Algebras/index-algebras.md"}
  - {"title": "Clifford Algebras", "source": "https://docs.magma-maths.org/v2.30-1/Algebras/CliffordAlgebras/index-clifford-algebras.md"}
prev: {"title": "The Main Involutions", "source": "https://docs.magma-maths.org/v2.30-1/Algebras/CliffordAlgebras/involutions.md"}
next: {"title": "Vector and Spin Representations", "source": "https://docs.magma-maths.org/v2.30-1/Algebras/CliffordAlgebras/spin.md"}
intrinsics:
  - {"name": "HomogeneousComponent", "signature": "HomogeneousComponent(v, k): AlgClffElt, RngIntElt -> AlgClffElt"}
  - {"name": "EvenSubalgebra", "signature": "EvenSubalgebra(C : parameters): AlgClff -> AlgAss, Map"}
  - {"name": "Centre", "signature": "Centre(C): AlgClff -> AlgAss, Map"}
  - {"name": "Center", "signature": "Center(C): AlgClff -> AlgAss, Map"}
examples:
  - "ex-40ad8c"
  - "ex-521a9d"
  - "ex-d39588"
  - "ex-04b7d8"
  - "ex-a8b683"
---

# Clifford Algebra Structure

Clifford algebras are associative structure constant algebras and therefore the intrinsics in chapters on structure constant algebras and associative algebras may be used with Clifford algebra arguments.

<a id="function-homogeneouscomponent-algclffelt-rngintelt"></a>
## `HomogeneousComponent(v, k): AlgClffElt, RngIntElt -> AlgClffElt`

The homogeneous component of degree $k$ of the Clifford algebra element $v$.

<a id="example-ex-40ad8c"></a>
## `Example: Homogeneous Components of an Element (ex-40ad8c)`

```magma
> F := GF(5);
> C,V,f := CliffordAlgebra(IdentityMatrix(F,4));
> v := (f(V.1)*f(V.2)+3*f(V.2))*(f(V.3)+f(V.4));
> AsPolynomial(HomogeneousComponent(v,2));
3*e1*e3 + 3*e2*e4
```

<a id="function-evensubalgebra-algclff"></a>
## `EvenSubalgebra(C : parameters): AlgClff -> AlgAss, Map`

The even subalgebra $C_+$ of the Clifford algebra $C$. This is the algebra of fixed points of the main involution. The second return value of this function is the canonical embedding of $C_+$ in $C$.

<a id="example-ex-521a9d"></a>
## `Example: Quaternions as an Even Subalgebra (ex-521a9d)`

A (generalised) quaternion algebra can also be realised as the even subalgebra of a Clifford algebra.

```magma
> F<a,b> := RationalFunctionField(Rationals(),2);
> Q := DiagonalMatrix(F,[1,-a,-b]);
> C,V,f := CliffordAlgebra(Q);
> E, h := EvenSubalgebra(C);
> i := E.2;
> j := E.3;
> i^2;
(a 0 0 0)
> j^2;
(b 0 0 0)
> i*j eq -j*i;
true
```

<a id="function-centre-algclff"></a>
## `Centre(C): AlgClff -> AlgAss, Map`

<a id="function-center-algclff"></a>
## `Center(C): AlgClff -> AlgAss, Map`

The centre of the Clifford algebra $C$. The second return value is the embedding in $C$.

The following examples illustrate the fact that over a finite field $F$ a Clifford algebra $C$ of a non-degenerate quadratic form $Q$ is either a simple algebra or the direct sum of two simple algebras. Furthermore, the same is true of its even subalgebra $E$. Let $V$ denote the quadratic space of $Q$.

<a id="example-ex-d39588"></a>
## `Example: Even Dimension with Maximal Witt Index (ex-d39588)`

If the dimension of $V$ is $2m$ and the Witt index of $Q$ is $m$, then $C$ is a central simple algebra.

```magma
> F := GF(3);
> Q := StandardQuadraticForm(6,F);
> C,V,f := CliffordAlgebra(Q);
> WittIndex(V);
3
> IsSimple(C);
true
> #Centre(C);
3
```

The even subalgebra $E$ of $C$ is the direct sum of two simple ideals $E(1-z)$ and $E(1+z)$, where $z^2 = 1$ and $z$ anticommutes with every element of $V$.

```magma
> E,h := EvenSubalgebra(C);
> IsSimple(E);
false
> #MinimalIdeals(E);
2
> Z := Centre(E); Z;
Associative Algebra of dimension 2 with base ring GF(3)
> #{ z : z in Z | IsUnit(z) };
4
> exists(z){ z : z in Z | z^2 eq One(E) and
>   forall{ v : v in V | f(v)*h(z) eq - h(z)*f(v) } };
true
> E1 := ideal< E | 1-z >;
> IsSimple(E1);
true
> E2 := ideal< E | 1+z >;
> IsSimple(E2);
true
```

<a id="example-ex-04b7d8"></a>
## `Example: Even Dimension with Non-Maximal Witt Index (ex-04b7d8)`

If $\dim V = 2m$ and the Witt index of $Q$ is $m-1$, the even subalgebra of $C$ is a simple algebra whose centre is a quadratic extension of $F$.

```magma
> F := GF(3);
> Q := StandardQuadraticForm(6,F : Minus);
> C,V,f := CliffordAlgebra(Q);
> WittIndex(V);
2
> IsSimple(C);
true
> #Centre(C);
3
> E := EvenSubalgebra(C);
> IsSimple(E);
true
> Z := Centre(E); Z;
Associative Algebra of dimension 2 with base ring GF(3)
> #{ z : z in Z | IsUnit(z) };
8
```

<a id="example-ex-a8b683"></a>
## `Example: Clifford Algebra in Odd Dimension (ex-a8b683)`

If $\dim V = 2m+1$ and the Witt index of $Q$ is $m$, the even subalgebra is central simple and $C$ is the either simple or the direct sum of two simple algebras.

```magma
> F := GF(3);
> Q := StandardQuadraticForm(5,F);
> C,V,f := CliffordAlgebra(Q);
> WittIndex(V);
2
> IsSimple(C);
false
> Z := Centre(C); Z;
Associative Algebra of dimension 2 with base ring GF(3)
> #{ z : z in Z | IsUnit(z) };
4
> E := EvenSubalgebra(C);
> IsSimple(E);
true
```

In this example the Clifford algebra is the direct sum of two simple ideals. But it is possible that the Clifford algebra of a scalar multiple of $Q$ is a simple algebra over a quadratic extension of the base field.

```magma
> C,V,f := CliffordAlgebra(2*Q);
> IsSimple(C);
true
> #Z,#{ z : z in Centre(C) | IsUnit(z) };
9 8
```

The non-zero elements of $Z$ are invertible and hence $Z$ is a field, namely ${\bf F}_{9}$.
