Basic Invariants

Field(A): ArtRep -> FldNum

Number field \(K\) such that \(A\) factors through the Galois group of the normal closure of \(K\).

BaseField(A): ArtRep -> Fld

The field \(F\) over which \(A\) is a representation of \({\Gal}(\bar F/F)\). This is \({\Q}\) unless \(A\) was constructed as a relative Artin representation, in which case it is the base field of the defining relative extension.

Degree(A): ArtRep -> RngIntElt
Dimension(A): ArtRep -> RngIntElt

Degree (=dimension) of an Artin representation \(A\).

Group(A): ArtRep -> GrpPerm

The Galois group \({\Gal}(L/{\Q})\) of the Galois closure \(L\) of Field(A), through which \(A\) factors. For a relative Artin representation \(A\) over \(F\), it is the subgroup \({\Gal}(L/F)\).

Character(A): ArtRep -> AlgChtrElt

Character of an Artin representation \(A\), represented as a complex-valued character of Group(A).

Conductor(A): ArtRep -> RngIntElt

Conductor of an Artin representation \(A\) (which must be a true representation, i.e. its character is not allowed to be a generalized character). Computes all the necessary local information if Artin representations were defined with Ramification:=false, so the first call to this function might take some time.

ConductorIdeal(A): ArtRep -> RngOrdIdl

The Artin conductor of a relative Artin representation \(A\), as an ideal of the ring of integers of its base field \(F={\tt BaseField(A)}\). As for Conductor, \(A\) must be a true representation, and the local information at the ramified primes is computed on demand if the Artin representations were defined with Ramification:=false. In addition, Field(A) must be Galois over \({\Q}\), that is, it must be its own Galois closure; representations attached to any other field are rejected with an error. The base field \(F\) need not be normal over \({\Q}\). The conductor is supported above the rational primes that ramify in Field(A), which are read off the factorization of the discriminant of DefiningPolynomial(A). A prime of a part that this factorization leaves unfactored is unramified when it does not divide the discriminant of Integers(Field(A)), so ConductorIdeal then computes that discriminant, and refuses when it has a factor in common with the unfactored part (see the parameter FactorDiscriminant of ArtinRepresentations, which takes effect only in the first call that computes Field(A)).

For a relative representation Conductor(A) is the conductor of the induction of \(A\) to \({\Q}\), and the two are related by conductor-inductivity,

\[{\tt Conductor(A)} = |d_F|^{\dim A}\cdot{\tt AbsoluteNorm(ConductorIdeal(A))},\]

where \(d_F\) is the absolute discriminant of \(F\). The absolute value matters, as \(d_F\) is negative when \(F\) has an odd number of complex places. When \(F\) is given as an extension of a field other than \({\Q}\), Norm and Discriminant return ideals of that field, so the absolute versions are needed.

ConductorExponent(A, P): ArtRep, RngOrdIdl -> RngIntElt

The exponent of a prime \(P\) of the base field \(F\) of a relative Artin representation \(A\) in the Artin conductor of \(A\), in other words the valuation at \(P\) of ConductorIdeal(A). It is 0 when \(A\) is unramified at \(P\), and \(P\) is allowed to be wildly ramified. As for ConductorIdeal, \(A\) must be a true representation and Field(A) its own Galois closure over \({\Q}\). \(P\) must be a nonzero prime ideal of the ring of integers of \(F\) itself: a prime of an order of \(F\) that is not maximal can lie under several primes of that ring, so it is rejected with an error.

Example: Conductors over the Base Field (ex-6f202c)

Run in calculator (opens in a new tab)

The quadratic character of \(K(\sqrt2)/K\) with \(K={\Q}(i)\) is ramified only at the prime above 2, where the ramification is wild, so the exponent there is larger than 1:

> K<i> := QuadraticField(-1);
> R<x> := PolynomialRing(K);
> A := ArtinRepresentations(ext<K | x^2-2>)[2];
> OK := Integers(K);
> P2 := Decomposition(OK,2)[1][1];
> ConductorExponent(A,P2);
4
> ConductorExponent(A,Decomposition(OK,13)[1][1]);
0
> ConductorIdeal(A) eq P2^4;
true

The conductor of the induction of \(A\) to \({\Q}\) is recovered from it by conductor-inductivity:

> Conductor(A);
64
> Abs(AbsoluteDiscriminant(OK))^Degree(A)*AbsoluteNorm(ConductorIdeal(A));
64

Run in calculator (opens in a new tab)

Decomposition(A): ArtRep -> SeqEnum[Tup]

Decompose an Artin representation \(A\) into irreducible constituents. Returns a sequence of tuples [...<A_i,n_i>...] with \(A_i\) irreducible and \(n_i\) its exponent in \(A\) (nonzero but possibly negative). If \(A\) is a relative Artin representation, the decomposition is taken in the Galois group over its base field, and the \(A_i\) are relative Artin representations over that same base field.

RationalDecomposition(A): ArtRep -> SeqEnum[Tup]

Decompose an Artin representation \(A\) into constituents with rational-valued characters, each corresponding to a Galois conjugacy class of irreducibles. Returns a sequence of tuples [...<A_i,n_i>...] with \(A_i\) having rational-valued character and \(n_i\) its exponent in \(A\) (nonzero but possibly negative). As with Decomposition, a relative Artin representation decomposes into relative Artin representations over the same base field.

Example: Decomposing Artin Representations (ex-12f333)

Run in calculator (opens in a new tab)

We give an example to show the difference between these decompositions.

> K := NumberField(PolynomialWithGaloisGroup(12,15));
> DefiningPolynomial(K);
x^12 - 24*x^10 + 216*x^8 - 896*x^6 + 1680*x^4 - 1152*x^2 + 48
> GroupName(GaloisGroup(K));
C3:D4
> c := PermutationCharacter(K);
> Decomposition(c);
[ <Artin representation C3:D4: (1,1,1,1,1,1,1,1,1) of K, 1>,
  <Artin representation C3:D4: (1,1,1,-1,1,-1,1,1,1) of K, 1>,
  <Artin representation C3:D4: (2,2,2,0,-1,0,-1,-1,-1) of K, 2>,
  <Artin representation C3:D4: (2,-2,0,0,2,0,0,0,-2) of K, 1>,
  <Artin representation C3:D4: (2,-2,0,0,-1,0,-1-2*J,1+2*J,1) of K, 1>,
  <Artin representation C3:D4: (2,-2,0,0,-1,0,1+2*J,-1-2*J,1) of K, 1> ]
> RationalDecomposition(c);
[ <Artin representation C3:D4: (1,1,1,1,1,1,1,1,1) of K, 1>,
  <Artin representation C3:D4: (1,1,1,-1,1,-1,1,1,1) of K, 1>,
  <Artin representation C3:D4: (2,2,2,0,-1,0,-1,-1,-1) of K, 2>,
  <Artin representation C3:D4: (2,-2,0,0,2,0,0,0,-2) of K, 1>,
  <Artin representation C3:D4: (4,-4,0,0,-2,0,0,0,2) of K, 1>];

Run in calculator (opens in a new tab)

DefiningPolynomial(A): ArtRep -> RngUPolElt

Returns the polynomial whose roots Group(A) permutes.

Minimize(A): ArtRep -> ArtRep
Optimize: BoolElt                    Default: true

Returns \(A\) attached to the smallest number field \(K\) such that \(A\) factors through its Galois closure. If Optimize := true, attempts to minimize the defining polynomial of \(K\) using OptimizedRepresentation. Raises an error when \(A\) is a relative Artin representation, as this is not implemented over a base field other than \(\Q\).

OptimizedRepresentation(A): ArtRep -> ArtRep

Returns the same Artin representation, but over an isomorphic version of the field that has had its representation optimized. Raises an error when \(A\) is a relative Artin representation, as this is not implemented over a base field other than \(\Q\).

Kernel(A): ArtRep -> FldNum

Smallest Galois extension \(K\) of the rationals through which \(A\) factors. Note that this field may be enormous and incomputable. For a relative Artin representation this is instead the smallest extension of the base field, Galois over it, through which \(A\) factors. In both cases the result is returned as a number field over \(\Q\).

Example: Minimising an Artin Representation (ex-9129cc)

Run in calculator (opens in a new tab)

We take an \(S_4\)-extension of \({\Q}\) and compute its Artin representations.

> R<x> := PolynomialRing(Rationals());
> K := NumberField(x^4+9*x-2);
> A := ArtinRepresentations(K);
> [Dimension(a): a in A];
[ 1, 1, 2, 3, 3 ]

Then we minimize the 2-dimensional one, which factors through an \(S_3\)-quotient.

> B := Minimize(A[3]); B;
Artin representation S3: (2,0,-1) of ext<Q|x^3+8*x+81>
> Kernel(B);
Number Field with defining polynomial x^6 + 48*x^4 + 576*x^2 + 179195
   over the Rational Field

Run in calculator (opens in a new tab)

IsIrreducible(A): ArtRep -> BoolElt

Return true iff a given Artin representation is irreducible as a complex representation.

IsRamified(A, p): ArtRep, RngIntElt -> BoolElt

Return true iff a given Artin representation is ramified at \(p\). For a relative Artin representation, this is ramification of the induction to \({\Q}\), so it asks whether \(p\) ramifies in the representation induced from the base field, not whether one particular prime above \(p\) does.

IsWildlyRamified(A, p): ArtRep, RngIntElt -> BoolElt

Return true iff a given Artin representation is wildly ramified at \(p\). For a relative Artin representation, this too is read from the induction to \({\Q}\).

EulerFactor(A, p): ArtRep, RngIntElt -> RngUPolElt
R: Rng                    Default: Universe(Eltseq(Character(A)))

The local polynomial (Euler factor) of an Artin representation \(A\) at the prime \(p\). It is the inverse characteristic polynomial of (arithmetic) Frobenius at \(p\) on the inertia-invariant subspace of \(A\). For a relative \(A\), this is the factor of its induction to \({\Q}\). \(A\) must not be virtual.

R is the coefficient ring of the result and defaults to Universe(Eltseq(Character(A))). When R is a cyclotomic field of order 1 or 2, as the default is for a rational-valued character, the result has integer coefficients.

EulerFactor(A, P): ArtRep, RngOrdIdl -> RngUPolElt
R: Rng                    Default: Universe(Eltseq(Character(A)))

The local polynomial (Euler factor) of a relative Artin representation \(A\) at a prime \(P\) of its base field. It is the inverse characteristic polynomial of (arithmetic) Frobenius at \(P\) on the inertia-invariant subspace, with the variable raised to the residue degree \(f(P/p)\) over \({\Q}\).

R is the coefficient ring of the result and defaults to Universe(Eltseq(Character(A))). When R is a cyclotomic field of order 1 or 2, as the default is for a rational-valued character, the result has integer coefficients.

This is the single local factor at \(P\). For a rational prime \(p\), EulerFactor(A, p) gives the factor of the induction to \({\Q}\), which is the product over all primes above \(p\). Thus the product of EulerFactor(A, P) over all \(P \mid p\) equals EulerFactor(A, p).

The base field need not be normal over \({\Q}\) and may be given as a tower. The field of \(A\) must be its own Galois closure over \({\Q}\); otherwise, an error results. \(A\) must not be virtual. As for ConductorExponent, \(P\) must be a nonzero prime ideal of the ring of integers of the base field itself, and a prime of an order that is not maximal is rejected with an error.

DecompositionGroup(A, P): ArtRep, RngOrdIdl -> GrpPerm
InertiaGroup(A, P): ArtRep, RngOrdIdl -> GrpPerm

The decomposition group, respectively the inertia group, at \(P\) of a relative Artin representation \(A\), where \(P\) is a prime of the base field \(F\) of \(A\). Both are returned as subgroups of Group(A), which is the quotient \({\Gal}(K/F)\) of \({\Gal}(\bar F/F)\) for \(K={\tt Field(A)}\). They are the groups of one prime \(Q\) of \(K\) above \(P\), the same prime for DecompositionGroup, InertiaGroup, RamificationGroup and LocalCharacter at \(P\). Another choice of \(Q\) conjugates them in Group(A), so only their conjugacy classes depend on \(P\) alone. \(A\) must be relative and Field(A) must be its own Galois closure over \({\Q}\). The base field \(F\) need not be normal over \({\Q}\), and may be given as a tower. As for ConductorExponent, \(P\) must be a nonzero prime ideal of the ring of integers of \(F\) itself, and a prime of an order that is not maximal is rejected with an error. See also RamificationGroup(A, P, i) and LocalCharacter(A, P).

RamificationGroup(A, P, i): ArtRep, RngOrdIdl, RngIntElt -> GrpPerm

The \(i\)-th ramification group \(G_i\) at \(P\) of a relative Artin representation \(A\), in lower numbering, again as a subgroup of Group(A); here \(P\) is a prime of the base field of \(A\) and \(i\ge-1\). Lower numbering is the numbering compatible with passing to a subgroup, so this is \(G_i(Q/p)\cap{\Gal}(K/F)\), where \(K={\tt Field(A)}\), \(Q\) is the prime of \(K\) above \(P\) that DecompositionGroup(A, P) uses, and \(p\) is the rational prime below \(P\). \(G_0\) is InertiaGroup(A, P) and \(G_{-1}\) is DecompositionGroup(A, P). The convention at \(i=-1\) differs from RamificationGroup(Q, i) for a prime ideal \(Q\), whose condition on \(\sigma\) is vacuous at \(i=-1\) and which therefore returns the whole group there. As for DecompositionGroup(A, P), \(A\) must be relative and Field(A) must be its own Galois closure over \({\Q}\), and \(P\) must be a nonzero prime ideal of the ring of integers of the base field itself; a prime of an order that is not maximal is rejected with an error. See also ConductorExponent(A, P).

LocalCharacter(A, P): ArtRep, RngOrdIdl -> AlgChtrElt

The restriction of a relative Artin representation \(A\) to its decomposition group at \(P\), a prime of the base field of \(A\). This is a character of DecompositionGroup(A, P), not an Artin representation. With the ramification groups RamificationGroup(A, P, i) it determines the conductor exponent. The Euler factor of \(A\) at \(P\), which EulerFactor(A, P) returns, also needs the Frobenius coset of the inertia group. As for DecompositionGroup(A, P), \(A\) must be relative and Field(A) must be its own Galois closure over \({\Q}\), and \(P\) must be a nonzero prime ideal of the ring of integers of the base field itself; a prime of an order that is not maximal is rejected with an error. See also EulerFactor(A, P) and ConductorExponent(A, P).

EpsilonFactor(A): ArtRep -> FldComElt

Global epsilon-factor \(\epsilon(A)\) of an Artin representation. Currently only implemented in a few basic cases, and raises an error otherwise. See Example Example: Local and Global Epsilon Factors for Dirichlet Characters.

RootNumber(A): ArtRep -> FldComElt

Global root number \(\epsilon(A)/|\epsilon(A)|\) of an Artin representation. Currently only implemented in a few basic cases, and raises an error otherwise. See Example Example: Local and Global Epsilon Factors for Dirichlet Characters.

EpsilonFactor(A, p): ArtRep, RngIntElt -> FldComElt

Local epsilon-factor \(\epsilon(A)\) of an Artin representation at \(p\). Currently only implemented in a few basic cases, and raises an error otherwise. See Example Example: Local and Global Epsilon Factors for Dirichlet Characters.

RootNumber(A, p): ArtRep, RngIntElt -> FldComElt

Local root number \(\epsilon_p(A)/|\epsilon_p(A)|\) of an Artin representation at \(p\). Currently only implemented in a few basic cases, and raises an error otherwise. See Example Example: Local and Global Epsilon Factors for Dirichlet Characters.

EpsilonFactor(A, infty): ArtRep, Infty -> FldComElt
RootNumber(A, infty): ArtRep, Infty -> FldComElt

Local root number \(w_\infty(A)\) of an Artin representation at infinity. See Example Example: Local and Global Epsilon Factors for Dirichlet Characters.

Example: Invariants of Artin Representations (ex-2bf31b)

Run in calculator (opens in a new tab)

Here are the invariants of Artin representations that factor through the splitting field of \(x^4-3\), a \(D_4\)-extension of \({\Q}\).

> R<x> := PolynomialRing(Rationals());
> K := NumberField(x^4-3);
> A := ArtinRepresentations(K);
> Degree(Kernel(A[5]),Rationals());
8
> [Dimension(a): a in A];
[ 1, 1, 1, 1, 2 ]
> Character(A[5]);
( 2, -2, 0, 0, 0 )
> [Conductor(a): a in A];
[ 1, 12, 3, 4, 576 ]
> [IsRamified(a,3): a in A];
[ false, true, true, false, true ]
> [IsWildlyRamified(a,3): a in A];
[ false, false, false, false, false ]
> EulerFactor(A[5],5);
$.1^2 + 1
> EpsilonFactor(A[5],3);
-3

Run in calculator (opens in a new tab)

Example: Euler Factors at Primes of the Base Field (ex-64a8da)

Run in calculator (opens in a new tab)

For a representation of \({\Gal}(\bar F/F)\), the Euler factor can be taken at a prime of \(F\) rather than at a rational prime. Here \(F={\Q}(2^{1/3})\), which is not normal over \({\Q}\), and \(E=F(\zeta_3)\). Above \(5\), the base field has one prime of residue degree \(1\) and one of residue degree \(2\), and the product of the two local factors is the Euler factor of the induction to \({\Q}\).

> R<x> := PolynomialRing(Rationals());
> F<a> := NumberField(x^3-2);
> T<t> := PolynomialRing(F);
> E := ext<F | t^2+t+1>;
> A := ArtinRepresentations(E);
> [Dimension(a): a in A];
[ 1, 1 ]
> OF := Integers(F);
> dec := Decomposition(OF,5);
> [<InertiaDegree(d[1]),RamificationIndex(d[1])>: d in dec];
[ <1, 1>, <2, 1> ]
> P := [d[1]: d in dec | InertiaDegree(d[1]) eq 1][1];
> EulerFactor(A[2],P);
$.1 + 1
> &*[EulerFactor(A[2],d[1]): d in dec];
-$.1^3 - $.1^2 + $.1 + 1
> EulerFactor(A[2],5);
-$.1^3 - $.1^2 + $.1 + 1

Run in calculator (opens in a new tab)

DirichletCharacter(A): ArtRep -> GrpDrchElt

Convert a one-dimensional Artin representation to a Dirichlet character. Raises an error when \(A\) is a relative Artin representation, as this is not implemented over a base field other than \(\Q\).

HeckeCharacter(A): ArtRep -> GrpHeckeElt

Convert a one-dimensional Artin representation \(A\) to a Hecke character. This is more natural than the previous, as in general Hecke characters will have \(L\)-functions matching that of the Artin representation, while Dirichlet characters only necessarily have \(L\)-functions when defined over the rationals. Raises an error when \(A\) is a relative Artin representation, as this is not implemented over a base field other than \(\Q\).

ArtinRepresentation(ch): GrpDrchElt -> ArtRep
field: FldNum                    Default: 

Convert a Dirichlet character ch to a one-dimensional Artin representation \(A\). To avoid recomputation, the minimal field through which \(A\) factors may be supplied by the field parameter. This now uses class field theory (thanks to C. Fieker).

Example: One-Dimensional Artin Representations (ex-db71ab)

Run in calculator (opens in a new tab)

An example that goes back and forth between the Dirichlet character and the Artin representation.

> load galpols;
> f := PolynomialWithGaloisGroup(8,46); // order 576
> K := NumberField(f); // octic field
> A := ArtinRepresentations(K);
> [Degree(a) : a in A];
[ 1, 1, 1, 1, 4, 4, 6, 6, 9, 9, 9, 9, 12 ]
> [Order(Character(Determinant(a))) : a in A];
[ 1, 2, 4, 4, 2, 2, 2, 1, 1, 2, 4, 4, 2 ]
> chi := DirichletCharacter(A[3]); // order 4
> Conductor(chi), Conductor(chi^2);
215 5
> Minimize(ArtinRepresentation(chi)); // disc = N(chi)^2*N(chi^2)
Artin representation C4: (1,-1,-I,I) of ext<Q|x^4+x^3-54*x^2-54*x+551>
> Factorization(Discriminant(Integers(Field($1))));
[ <5, 3>, <43, 2> ]

Run in calculator (opens in a new tab)