\(L\)-series#

Creation#

The LSeries command creates the \(L\)-series \(L(A,s)\) associated to a modular abelian variety \(A\) over \({\mathbb{Q}}\) or a cyclotomic field. No actual computation is performed.

LSeries(A): ModAbVar -> ModAbVarLSer#: The \(L\)-series associated to the abelian variety \(A\).

Example: Lser Creation (ex-1dae21)#

> A := JZero(23);
> L := LSeries(A);
> L;
L(JZero(23),s): L-series of Modular abelian variety JZero(23) of
dimension 2 and level 23 over Q
> LSeries(ModularAbelianVariety("65B"));
L(65B,s): L-series of Modular abelian variety 65B of dimension 2
and level 5*13 over Q

Run in calculator

You can create \(L\)-series of abelian varieties over cyclotomic fields, but currently no interesting functionality is implemented for them.

> LSeries(BaseExtend(JZero(11),CyclotomicField(5)));
L(JZero(11),s): L-series of Modular abelian variety JZero(11) of
dimension 1 and level 11 over Q(zeta_5)

Run in calculator

Invariants#

CriticalStrip(L): ModAbVarLSer -> RngIntElt, RngIntElt#: Let \(L\) be the \(L\)-function of some modular abelian variety \(A\). This function returns integers \(x\) and \(y\) such that the critical strip for \(L\) is the set of complex numbers with real part strictly between \(x\) and \(y\). If \(W\) is the set of weights of newforms that give rise to factors of \(A\), then this command returns \(0\) and Max(W).

ModularAbelianVariety(L): ModAbVarLSer -> ModAbVar#: The abelian variety the \(L\)-series \(L\) is associated to.

Example: Lser Invariants (ex-c8a997)#

We define several \(L\)-functions of modular abelian varieties and modular motives, and compute their critical strip (which is from \(0\) to \(k\), where \(k\) is the weight).

> L := LSeries(JZero(37));
> CriticalStrip(L);
0 2
> L := LSeries(JZero(37,6));
> CriticalStrip(L);
0 6
> J := JOne(11,3);  J;
Modular motive JOne(11,3) of dimension 5 and level 11 over Q
> CriticalStrip(LSeries(J));
0 3
> A_delta := JZero(1,12);
> L := LSeries(A_delta);
> CriticalStrip(L);
0 12
> ModularAbelianVariety(L);
Modular motive JZero(1,12) of dimension 1 and level 1 over Q

Run in calculator

Characteristic Polynomials of Frobenius Elements#

Let \(A\) be a modular abelian variety. The characteristic polynomials of Frobenius elements acting on the \(\ell\)-adic Tate modules of \(A\) define the local \(L\)-factors of \(L(A,s)\).

FrobeniusPolynomial(A : parameters): ModAbVar -> RngUPolElt#

Factored: BoolElt                    Default: false

The characteristic polynomial of Frobenius on the abelian variety \(A\) defined over a finite field. If Factored is set to true, return a factorization instead of a polynomial.

FrobeniusPolynomial(A, p : parameters): ModAbVar, RngIntElt -> RngUPolElt#

Factored: BoolElt                    Default: false

The characteristic polynomial of \({\rm Frob}_p\) acting on any \(\ell\)-adic Tate module of the abelian variety \(A\) over a number field, where \(p\) and \(\ell\) do not divide the level of \(A\). If the base ring has degree bigger than \(1\), then return a sequence of characteristic polynomials, one for each prime lying over \(p\), sorted by degree. If Factored is set to true, return a factorization instead of a polynomial.

FrobeniusPolynomial(A, P): ModAbVar, RngOrdIdl -> RngUPolElt#: The characteristic polynomial of Frobenius at the nonzero prime ideal \(P\) of a number field on the modular abelian variety \(A\), where \(P\) is assumed to be a prime of good reduction for \(A\), and \(A\) is defined over a field that contains the prime \(P\).

Example: Lser Characteristic Polynomials Of Frobenius Elements (ex-671a3a)#

> A := JZero(23);
> FrobeniusPolynomial(A,2);
x^4 + x^3 + 3*x^2 + 2*x + 4
> A := JZero(23) * JZero(11,4) * JOne(13);
> FrobeniusPolynomial(A,2);
x^12 + 2*x^11 + 17*x^10 + 40*x^9 + 145*x^8 + 362*x^7 + 798*x^6 +
    1408*x^5 + 2104*x^4 + 2528*x^3 + 2528*x^2 + 1792*x + 1024
> Factorization($1);
[
    <x^4 - 2*x^3 + 14*x^2 - 16*x + 64, 1>,
    <x^4 + x^3 + 3*x^2 + 2*x + 4, 1>,
    <x^4 + 3*x^3 + 5*x^2 + 6*x + 4, 1>
]
> A := BaseExtend(JZero(23),CyclotomicField(22));
> FrobeniusPolynomial(A,2);
[
    x^4 + 25*x^3 - 327*x^2 + 25600*x + 1048576
]

Run in calculator

These characteristic polynomials are used in the algorithm to compute the number of points on modular abelian varieties over finite fields.

> A := ChangeRing(JZero(23),GF(2^10));
> NumberOfRationalPoints(A);
1073875 1073875
> Factorization($1);
[ <5, 3>, <11, 2>, <71, 1> ]

Run in calculator

Values at Integers in the Critical Strip#

Magma allows evaluation of \(L\)-series at integers lying within the critical strip.

There exist algorithms for computing \(L(A,s)\) for any complex number \(s\), but these are not currently implemented in Magma.

L(s): RngIntElt, ModAbVarLSer -> RngElt#
Evaluate(L, s): ModAbVarLSer, RngIntElt -> FldReElt#
Evaluate(L, s, prec): ModAbVarLSer, RngIntElt, RngIntElt -> FldReElt#: The value of \(L\)-series \(L\) at \(s\), where \(s\) must be an integer that lies in the critical strip for \(L\), computed using \(prec\) terms of the power series or \(100\) if \(prec\) is not given. The power series used are the \(q\)-expansions of modular forms corresponding to differentials on \(A\). It is not clear, a priori, what the relation is between \(prec\) and the precision of the real number output by this command. (It is theoretically possible to give bounds, but we have not done this.) In practice, one can increase \(prec\) and see how the output result changes.

LRatio(A, s): ModAbVar, RngIntElt -> FldRatElt#
LRatio(L, s): ModAbVarLSer, RngIntElt -> FldRatElt#: Given an abelian variety \(A\) over \({\mathbb{Q}}\) attached to a newform or an \(L\)-series \(L\) of an abelian variety and an integer \(s\), return the ratio \(L(A,s)*(s-1)!/((2\pi )^{s-1}*\Omega _s)\), where \(s\) is a “critical integer”, and \(\Omega _s\) is the integral (Neron) volume of the group of real points on the optimal quotient \(A'\) associated to \(A\) when \(s\) is odd, and the volume of the \(-1\) eigenspace for conjugation when \(s\) is even.

IsZeroAt(L, s): ModAbVarLSer, RngIntElt -> BoolElt#: Given an \(L\)-series \(L\) of a modular abelian variety and an integer \(s\) in the critical strip for \(L\) return true is \(L(A, s)\) is zero. In contrast to the output of the Evaluate command above, the result returned by this command is provably correct.

Example: Lser Values At Integers In The Critical Strip (ex-88991d)#

First we demonstrate each evaluation command for the \(L\)-series of \(J_0(23)\).

> L := LSeries(JZero(23));
> L(1);
0.248431866590599284683305769290 +  0.E-29*i
> Evaluate(L,1);
0.248431866590599284683305769290 +  0.E-29*i
> Evaluate(L,1,200);
0.248431866590599681207250339074 +  0.E-29*i
> LRatio(L,1);
1/11
> L := LSeries(JZero(23));
> L(1);
0.248431866590599284683305770476 +  0.E-29*i
> Evaluate(L,1,200);
0.248431866590599681207250340144 +  0.E-29*i

Run in calculator

Next we compute the \(L\)-series of the motive attached to the weight \(12\) level \(1\) modular form \(\Delta\).

> A := JZero(1,12);
> L := LSeries(A);
> Evaluate(L,1);
0.0374412812685155417387703158443
> L(5);
0.66670918843400364382613022164
> Evaluate(L,1,200);
0.0374412812685155417387703158443
> LRatio(L,1);
11340/691
> LRatio(L,2);
24
> LRatio(L,3);
7

Run in calculator

We compute some ratios for \(J_1(N)\) and factors of \(J_1(N)\).

> LRatio(JOne(13),1);
1/361
> J := JOne(23);
> Evaluate(LSeries(J),1);
0.000000080777697074785775420090700066 +
0.000000053679621277482217773207669332*i

Run in calculator

It looks kind of like \(L(J_1(23),1)\) is zero. However, this is not the case! We can not compute LRatio for \(J_1(23)\), since it not attached to a newform. We can, however, compute LRatio for each simple factor.

> LRatio(J(1),1);
1/11
> LRatio(J(2),1);
1/1382426761

Run in calculator

Each simple factor has nonzero LRatio, so \(L(J,1)\neq 0\).

Leading Coefficient#

The \(L\)-function \(L(A,s)\) has a Taylor expansion about any critical integer. The leading coefficient and order of vanishing of \(L(A,s)\) about a critical integer can be computed.

LeadingCoefficient(L, s, prec): ModAbVarLSer, RngIntElt, RngIntElt -> FldReElt, RngIntElt#: Given an \(L\)-series \(L\) associated to a modular abelian variety \(A\) and an integer \(s\) in the critical strip for \(L\) return the leading coefficient of the Taylor expansion about \(s\) and the order of vanishing of \(L\) at \(s\). At present, \(A\) must have weight \(2\) and trivial character (so \(s=1)\). It does not have to be attached to a newform. The argument \(prec\) is the number of terms of the power series which are used.

Example: Lser Leading Coefficient (ex-54429e)#

> LeadingCoefficient(LSeries(JZero(37)),1,100);
0.244264064925838981349867782965 1
> LeadingCoefficient(LSeries(JZero(37)(1)) ,1,100);
0.305999773800085290044094075725 1
> J := JZero(3^5);
> LeadingCoefficient(LSeries(J),1,100);
15.140660788463628991688955015326 +  0.E-27*i 4

Run in calculator

The order of vanishing of \(4\) for \(J_0(3^5)\) comes from an elliptic curve and a \(3\)-dimensional abelian variety that have order of vanishing \(1\) and \(3\), respectively.

> LeadingCoefficient(LSeries(J(1)),1,100);
1.419209649338215616003188084281 1
> LeadingCoefficient(LSeries(J(5)),1,100);
1.228051952859142052034769858445 3

Run in calculator

Example: Lser Leading Coefficient2 (ex-b1fb66)#

We give a few more examples.

> L := LSeries(ModularAbelianVariety("389A",+1));
> LeadingCoefficient(L,1,100);
0.75931650029224679065762600319 2
>
> A := JZero(65)(2); A;
Modular abelian variety 65B of dimension 2, level 5*13 and
conductor 5^2*13^2 over Q
> L := LSeries(A);
> LeadingCoefficient(L,1,100);
0.91225158869818984109351402175 +  0.E-29*i 0
> A := JZero(65)(3); A;
Modular abelian variety 65C of dimension 2, level 5*13 and
conductor 5^2*13^2 over Q
> L := LSeries(A);
> LeadingCoefficient(L,1,100);
0.452067921768031069917486135000 +  0.E-29*i 0

Run in calculator