# Isotropic and Singular Vectors and Subspaces

Let $\beta$ be a reflexive bilinear or a sesquilinear form on the vector space $V$. A non-zero vector $v$ is *isotropic* (with respect to $\beta$) if $\beta(v,v) = 0$. If $Q$ is a quadratic form, a non-zero vector $v$ is *singular* if $Q(v) = 0$.

## `HasIsotropicVector(V): ModTupFld -> BoolElt, ModTupFldElt`

Determine whether the polar space $V$ contains an isotropic vector; if it does, the second return value is a representative.

## `HasSingularVector(V): ModTupFld -> BoolElt, ModTupFldElt`

Determine whether the quadratic space $V$ contains a singular vector; if it does, the second return value is a representative.

A subspace $W$ of a polar space is *totally isotropic* if every non-zero vector of $W$ is isotropic.

## `IsTotallyIsotropic(V): ModTupFld -> BoolElt`

Returns `true` if the polar space $V$ is totally isotropic, otherwise `false`.

A subspace $W$ of a quadratic space defined by a quadratic form $Q$ is *totally singular* if $Q(w) = 0$ for all $w\in W$.

## `IsTotallySingular(V): ModTupFld -> BoolElt`

Returns `true` if the quadratic space $V$ is totally singular, otherwise `false`.

## `MaximalTotallyIsotropicSubspace(V): ModTupFld -> ModTupFld`

A representative maximal totally isotropic subspace of the polar space $V$.

## `MaximalTotallySingularSubspace(V): ModTupFld -> ModTupFld`

A representative maximal totally singular subspace of the quadratic space $V$.

The *Witt index* of a polar space $V$ that is not a quadratic space is the dimension of a maximal totally isotropic space. The *Witt index* of a quadratic space is the dimension of a maximal totally singular subspace.

If the characteristic of the field is not 2 and if $\beta$ is the polar form of $Q$, a subspace is totally singular if and only if it is totally isotropic with respect to $\beta$; in this case the Witt index of $Q$ coincides with the Witt index of $\beta$.

## `WittIndex(V): ModTupFld -> RngIntElt`

The Witt index of the polar space $V$.

An ordered pair of vectors $(u,v)$ such that $u$ and $v$ are isotropic and $\beta(u,v) = 1$ is a *hyperbolic pair*. If $V$ is a quadratic space, $u$ and $v$ are required to be singular. The subspace spanned by a hyperbolic pair is a *hyperbolic plane*.

If $V$ is a pseudo-symplectic space defined by a symmetric bilinear form $\beta$ over a finite field of characteristic 2, define the *pseudo-radical* of $V$ to be the radical of the hyperplane $\{ v\in V\mid \beta(v,v) = 0\}$.

## `HyperbolicPair(V, u): ModTupFld, ModTupFldElt -> ModTupFldElt`

Given a singular or isotropic vector $u$ which is not in the radical or pseudo-radical, return a vector $v$ such that $(u,v)$ is a hyperbolic pair.

## `Example: pseudoalt (ex-ced2e7)`

The vector space of dimension 2 over ${\bf F}_{2}$ is pseudo-symplectic (the form is the identity matrix). It has three non-zero elements only one of which is isotropic. This confirms that not every isotropic vector in a non-degenerate pseudo-symplectic space belongs to a hyperbolic pair.

```magma
> V := VectorSpace(GF(2),2);
> IsPseudoSymplecticSpace(V);
true
> IsNondegenerate(V);
true
> { v : v in V | v ne V!0 and DotProduct(v,v) eq 0};
{
    (1 1)
}

```

A polar space $V$ has a *hyperbolic splitting*; namely, a direct sum decomposition

$$
V = L_1\perp L_2\perp \cdots\perp L_m \perp W
$$

where the $L_i$ are *hyperbolic planes* and $m$ is maximal.

The polar space is *hyperbolic* if $W = 0$; i.e., it is an orthogonal sum of hyperbolic planes. In Bourbaki [[Bourbaki, 2007](../../references.md#cite-bourbaki-forms), p. 66] the corresponding form is said to be *neutral*.

If the form defining the polar space is non-degenerate and not pseudo-alternating, then every isotropic (resp. singular) vector belongs to a hyperbolic pair. Therefore if the charactersistic is not 2, $W$ is *anisotropic*; i.e., it does not contain any isotropic vectors. In this case the integer $m$ is the *Witt index* of the form and $W$ is called the *anisotropic component* of the splitting.

If the characteristic is 2 and $V$ is a quadratic space, $W$ does not contain singular vectors but it may contain isotropic vectors.

## `Example: quadsplit (ex-b0692a)`

The last term of a hyperbolic splitting of a quadratic space in characteristic 2 can contain an isotropic vector.

```magma
> Q := StandardQuadraticForm(6,4 : Minus);
> V := QuadraticSpace(Q);
> WittIndex(V);
2
> H := HyperbolicSplitting(V);
> W := sub< V | H[2] >;
> HasSingularVector(W);
false
> HasIsotropicVector(W);
true (    0     0     1     0     0     0)

```

## `HyperbolicSplitting(V): ModTupFld -> Tup`

A pair $(M,B)$, where $M$ is a maximal list of pairwise orthogonal hyperbolic pairs and $B$ is a basis for the orthogonal complement of the subspace they span. This function requires the form to be non-degenerate and, except for symplectic spaces, the base ring of $V$ must be a finite field.

## `Example: hypsplit (ex-7e8c7f)`

Find the hyperbolic splitting of a polar space defined by a symmetric bilinear form. In this example $W$ is a non-degenerate subspace of the polar space $V$.

```magma
> K<a> := GF(7,2);
> J := Matrix(K,3,3,[1,2,1, 2,1,0, 1,0,2]);
> V := VectorSpace(K,3,J);
> W := sub<V| [a,a,a], [1,2,3]>;
> IsNondegenerate(W);
true
> HyperbolicSplitting(W);
<[
    [
        (a^20    1 a^39),
        (a^12    2    a)
    ]
], []>

```

## `Example: extradical (ex-621e11)`

The polar space $V$ of the previous example is degenerate and so `HyperbolicSplitting` cannot be applied directly. Instead, we first split off the radical.

```magma
> IsNondegenerate(V);
false
> R := Radical(V);
> H := (Dimension(R) eq 0) select V else
>   sub<V|[e : e in ExtendBasis(B,V) | e notin B] where B is Basis(R)>;
> HyperbolicSplitting(H);
<[
    [
        (   0 a^20    1),
        (   0 a^12    2)
    ]
], []>

```

A non-degenerate polar space $V$ of dimension $2m$ which is the direct sum of two totally isotropic subspaces is hyperbolic and it has a *symplectic basis*; i.e., a basis $e_1$, $f_1$, …, $e_m$, $f_m$ such that the pairs $(e_i, f_i)$, $1\le i\le m$ are mutually orthogonal hyperbolic pairs.

## `SymplecticBasis(V, U, W): ModTupFld, ModTupFld, ModTupFld -> [ModTupFldElt]`

Given totally isotropic subspaces $U$ and $W$ of a non-degnerate polar space $V$ such that $V = U\oplus W$, return a symplectic basis for $V$ such that $e_1$, $e_2$, …, $e_m$ is a basis for $U$ and $f_1$, $f_2$, …, $f_m$ is a basis for $W$.

Let $V = L_1\perp\cdots\perp L_m \perp W \perp \hbox{rad}(V)$ be a hyperbolic splitting of the polar space $V$ where the $L_i$ are hyperbolic planes spanned by hyperbolic pairs $(e_i,f_i)$ for $1\le i\le m$. The subspaces $P = \langle e_1,\dots,e_m\rangle$ and $N = \langle f_1,\dots,f_m\rangle$ are totally isotropic (resp. totally singular) and we call the $4$-tuple $(\hbox{rad}(V),P,N,W)$ a *Witt decomposition* of $V$.

## `WittDecomposition(V): ModTupFld -> SeqEnum[ModTupFld]`

The Witt decomposition of the space $V$.

## `WittDecomposition(M, a): AlgMatElt[FldFin], FldAut -> AlgMatElt[FldFin], AlgMatElt[FldFin]`

Given a field automorphism $a$, and a matrix $M$ which is hermitian with respect to $a$, returns the Gram matrix with respect to a basis of a Witt decomposition of the polar space of $M$, in the order $(P, N, W, \hbox{rad}(V))$. Also returns the basis matrix.

A quadratic space is *metabolic* if it is a direct sum $E\oplus F$ of totally singular subspaces $E$ and $F$ such that $E = E^\perp$.

Given a quadratic space with quadratic form $q : V \to F$, the *metabolic space* based on $V$ is the quadratic space $M = V\oplus V^*$ with quadratic form $Q : M \to F$ defined by $Q(v,f) = q(v) + vf$.

## `MetabolicSpace(V): ModTupFld -> ModTupFld`

The metabolic space based on the quadratic space $V$.