# The Standard Forms

This section describes the “standard” alternating, hermitian, quadratic and symmetric forms defined on a finite dimensional vector space over a field. These are forms of maximal Witt index together with the quadratic forms of non-maximal Witt index over finite fields (see Section [Isotropic and Singular Vectors and Subspaces](structure.md#sectstructure)). The standard forms are preserved by the Magma implementation of the classical groups over finite fields.

If $J$ is the matrix of a bilinear form, $X$ preserves the form if $XJX^\mathrm{tr}= J$. If $J$ represents an hermitian form and if $\overline{X}$ is obtained from $X$ by application of the field automorphism, then $X$ preserves the form if $XJ\overline{X}^\mathrm{tr}= J$.

If $\beta$ is a non-degenerate alternating form, then $\hbox{rad}(V)$ and the anisotropic component of a hyperbolic splitting are zero. Thus the dimension of $V$ must be even and $V$ has a basis of mutually orthogonal hyperbolic pairs. In particular, up to equivalence, there is only one non-degenerate alternating form on $V$.

## `StandardAlternatingForm(n, R): RngIntElt, Rng -> AlgMatElt`

## `StandardAlternatingForm(n, q): RngIntElt, RngIntElt -> AlgMatElt`

If $n = 2m$, this function returns the $n\times n$ matrix of a non-degenerate alternating form over the ring $R$ (or the field of $q$ elements) such that if $e_1$, $e_2$, …, $e_{2m}$ is the standard basis, then $(e_1,e_{2m})$, $(e_2,e_{2m-1})$, …, $(e_m,e_{m+1})$ are mutually orthogonal hyperbolic pairs.

The group of isometries of this form is the symplectic group $\hbox{Sp}(2m,R)$.

## `Example: alternatingform (ex-3c60cd)`

Create a symplectic geometry with the standard alternating form and then check that every non-zero vector is isotropic.

```magma
> K := GF(5);
> J := StandardAlternatingForm(4,K);
> J;
[0 0 0 1]
[0 0 1 0]
[0 4 0 0]
[4 0 0 0]
> V := VectorSpace(K,4,J);
> forall{ v : v in V | DotProduct(v,v) eq 0 };
true

```

## `StandardPseudoAlternatingForm(n, K): RngIntElt, Fld -> AlgMatElt`

## `StandardPseudoAlternatingForm(n, q): RngIntElt, RngIntElt -> AlgMatElt`

The matrix of the standard pseudo-alternating form of degree $n$ over the field $K$ (or the finite field of order $q$), which must have characteristic 2; that is, a symmetric form which is not alternating.

## `StandardHermitianForm(n, K): RngIntElt, Fld -> AlgMatElt, Map`

## `StandardHermitianForm(n, q): RngIntElt, RngIntElt -> AlgMatElt, Map`

The first return value of this function is the $n\times n$ anti-diagonal matrix $(\delta_{i,n-i+1})$ over the field $K$ (or the field of $q^2$ elements). If $K$ is the finite field of $q^2$ elements, the second return value is the field involution $K \to K :x \mapsto x^q$. If $K$ is a field which admits the operation of complex conjugation, the second return value is the field automorphism which sends each element to its complex conjugate.

If $\beta$ is a non-degenerate hermitian form over a finite field, then $\hbox{rad}(V)$ is zero and the dimension of the anisotropic component of a hyperbolic splitting is either 1 or 0.

In the finite field case, the group of isometries of this form is $\hbox{GU}(n,q)$.

## `StandardQuadraticForm(n, K : parameters): RngIntElt, Fld -> AlgMatElt`

## `StandardQuadraticForm(n, q : parameters): RngIntElt, RngIntElt -> AlgMatElt`

```magma
Minus  : BoolElt                      Default: false
Variant: MonStgElt                    Default: "Default"
```

An $n\times n$ upper triangular matrix representing a quadratic form over the field $K$ (or the field of order $q$). The default option is to return a form of maximal Witt index, namely the upper triangular matrix whose non-zero entries are $\delta_{i,n-i+1}$, where $1 \le i \le (n+1)/2$.

If `Minus` is `true` and $n = 2m$, this function returns a form whose Witt index is $m-1$. If `Minus` is `true`, $n = 2m+1$ and $K$ is a finite field of odd characteristic, the return value is a form of Witt index $m$ which is similar to but not congruent to the default form. Use the `Revised` option of `Variant` to obtain the form preserved by the orthogonal groups `AltGOMinus(n,q)` and subgroups.

If $K$ is a finite field of order $q$ and $W$ is the anisotropic component of a hyperbolic splitting of a form of even rank and `Minus` type, then $W$ has basis vectors $e$ and $f$ such that $Q(e) = -1$, $\beta(e,f) = -\xi-\xi^q$ and $Q(f) = -\xi\xi^q$, where $\xi$ is a primitive element of ${\bf F}_{q^2}$. If the characteristic of $K$ is odd, the `Revised` option returns a form corresponding to an orthonormal basis for $W$.

## `Example: minusform (ex-78f890)`

Construct a standard quadratic form of minus type.

```magma
> K<z> := GF(7,2);
> Q := StandardQuadraticForm(4,49 : Minus);
> Q;
[   0    0     0    1]
[   0    6     5    0]
[   0    0  z^29    0]
[   0    0     0    0]
> _<x> := PolynomialRing(K);
> a := Q[2,2] * Q[3,3];
> IsIrreducible(x^2+x+a);
true

```

## `Example: revisedminus (ex-29b8f5)`

Compare the revised form with the standard form: the forms `Q` above and `QR` below have different entries in the central $2\times 2$ block.

```magma
> QR := StandardQuadraticForm(4,49 : Minus, Variant := "Revised");
> QR;
[   0    0     0    1]
[   0    4     0    0]
[   0    0  z^11    0]
[   0    0     0    0]

```

## `StandardSymmetricForm(n, K): RngIntElt, Fld -> AlgMatElt`

## `StandardSymmetricForm(n, q : parameters): RngIntElt, RngIntElt -> AlgMatElt`

```magma
Minus  : BoolElt                      Default: false
Variant: MonStgElt                    Default: "Default"
```

In all cases this is $Q + Q^{\hbox{tr}}$, where $Q$ is the corresponding standard quadratic form, as defined above.