# Basic Invariants

## `BaseField(A): GalRep -> FldPad`

The base field $K$ of the Galois representation $A: \mathop{\rm Gal}\nolimits(\bar K/K)\to\mathop{\rm GL}\nolimits_m({\mathbb{C}})$.

## `Degree(A): GalRep -> RngIntElt`

## `Dimension(A): GalRep -> RngIntElt`

Degree ($=$dimension) $m$ of a Galois representation $A: \mathop{\rm Gal}\nolimits(\bar K/K)\to\mathop{\rm GL}\nolimits_m({\mathbb{C}})$

## `Example: Galrep Degree (ex-890f18)`

```magma
> K:=pAdicField(3,20);
> R<x>:=PolynomialRing(K);
> F:=ext<K|x^3-3>;
> list:=GaloisRepresentations(F,K);
> forall{A: A in list | BaseField(A) eq K};
true
> [Degree(A): A in list];
[ 1, 1, 2 ]

```

## `Group(A): GalRep -> GrpPerm`

## `GaloisGroup(A): GalRep -> GrpPerm`

Finite Galois group $\mathop{\rm Gal}\nolimits(F/K)$ that computes the finite part of a Galois representation, where $F$ is `Field(A)` and $K$ is `BaseField(A)`.

## `Example: Galrep Group (ex-baedd9)`

```magma
> K:=pAdicField(2,20);
> R<x>:=PolynomialRing(K);
> list1:=[PrincipalCharacter(K),CyclotomicCharacter(K),SP(K,3)];
> [Degree(A): A in list1];
[ 1, 1, 3 ]
> [GroupName(Group(A)): A in list1];
[ C1, C1, C1 ]
> list2:=GaloisRepresentations(x^4-2);
> [Degree(A): A in list2];
[ 1, 1, 1, 1, 2 ]
> [GroupName(Group(A)): A in list2];
[ D4, D4, D4, D4, D4 ]
> list1[1] eq list2[1];
true

```

## `FrobeniusElement(A): GalRep -> GrpPermElt`

An arithmetic Frobenius element of `Group(A)` for a Galois representation $A$.

## `Example: Galrep Frobeniuselement (ex-abc80d)`

Take $K={\mathbb{Q}}_2$ and $F={\mathbb{Q}}_2(\zeta_5)$, a degree 4 unramified extension of $K$. A Frobenius element $\mathop{\rm Frob}\nolimits\in\mathop{\rm Gal}\nolimits(F/K)$ is characterized by the property that $\mathop{\rm Frob}\nolimits(x)\equiv x^q\ \mathop{\rm mod}\ m_F$. In this example, $q=2$ (size of the residue field of $K$).

```magma
> K:=pAdicField(2,20);
> R<x>:=PolynomialRing(K);
> A:=GaloisRepresentations(x^4+x^3+x^2+x+1)[4]; A;
1-dim unramified Galois representation (1,-1,-zeta(4)_4,zeta(4)_4)
   with G=C4, I=C1 over Q2[20]
> frob:=FrobeniusElement(A); frob;
(1, 2, 4, 3)
> F<u>:=Field(A);
> Valuation(Automorphism(A,frob)(u)-u^2) gt 0;
true

```

## `Character(A): GalRep -> AlgChtrElt`

Character of the finite part of a Galois representation $A$. For this to be well-defined, $A$ must have only one component (and not several components with different characters).

## `Example: Galrep Character (ex-ce7d20)`

```magma
> K:=pAdicField(2,20);
> R<x>:=PolynomialRing(K);
> A1:=PrincipalCharacter(K);
> Character(A1);
( 1 )
> A2:=CyclotomicCharacter(K);
> Character(A2);
( 1 )
> A3:=PermutationCharacter(ext<K|3>,K);
> Character(A3);
( 3, 0, 0 )
> A1+A2+A3;
5-dim unramified Galois representation Unr(1-3/2*x+1/2*x^2) + (3,0,0)
   with G=C3, I=C1 over Q2[20]

```

## `Field(A): GalRep -> FldPad`

Given a Galois representation $A$, return the $p$-adic field $F$ such that the finite part of $A$ factors through $\mathop{\rm Gal}\nolimits(F/K)$, $K =$ `BaseField(A)`.

## `DefiningPolynomial(A): GalRep -> RngUPolElt`

For a Galois representation $A$ over $K$, returns a polynomial over $K$ whose splitting field is $F=$`Field(A)`. The Galois group $\mathop{\rm Gal}\nolimits(F/K)$ is represented as a permutation group `Group(A)` on the roots of this polynomial.

## `Example: Galrep Definingpolynomial (ex-216918)`

In this example $K={\mathbb{Q}}_5$ and $F/K$ is a dihedral extension of degree 12, represented as a splitting field of a degree 6 polynomial.

```magma
> K:=pAdicField(5,20);
> E:=EllipticCurve([K|0,5]);
> A:=GaloisRepresentation(E); A;
2-dim Galois representation Unr(sqrt(5)*i)*(2,-2,0,0,-1,1) with G=D6, I=C6,
   conductor 5^2 over Q5[20]
> Field(A);
Totally ramified extension defined by the polynomial x^6 - 5
 over Unramified extension defined by the polynomial x^2 + 4*x + 2
 over 5-adic field mod 5^20
> DefiningPolynomial(A);
x^6 + O(5^20)*x^5 + O(5^20)*x^4 + O(5^20)*x^3 + O(5^20)*x^2 + O(5^20)*x - 5 +
   O(5^20)

```

## `Automorphism(A, g): GalRep, GrpPermElt -> Map`

The automorphism of `Field(A)`$/$`BaseField(A)` given by $g$.

## `Example: Galrep Automorphism (ex-3bde84)`

In this example $K={\mathbb{Q}}_5$ and $F/K$ is a dihedral extension of degree 12, represented as a splitting field of the polynomial $x^6-5$.

```magma
> R<x>:=PolynomialRing(Rationals());
> K:=NumberField(x^6-5);
> a:=ArtinRepresentations(K)[6];
> A:=GaloisRepresentation(a,5); A;
2-dim Galois representation (2,-2,0,0,-1,1) with G=D6, I=C6, conductor 5^2
   over Q5[40]
> F:=Field(A); F;
Totally ramified extension defined by the polynomial x^6 - 5
 over Unramified extension defined by the polynomial x^2 + 4*x + 2
 over 5-adic field mod 5^40
> DefiningPolynomial(A);
x^6 - 5

```

The 12 elements $\sigma\in\mathop{\rm Gal}\nolimits(F/K)\cong D_6$ act on $\pi=\root 6 \of 5$ by multiplying it by 6th roots of unity, with $\sigma(\pi)=\pi$ for 2 of them, and $v(\sigma(\pi)-\pi)=1$ for the other 10.

```magma
> pi:=UniformizingElement(F);
> autF:=[* Automorphism(A,g): g in Group(A) *];
> [Valuation(sigma(pi)-pi): sigma in autF];
[ 241, 1, 1, 1, 1, 1, 240, 1, 1, 1, 1, 1 ]

```

## `EulerFactor(A): GalRep -> RngUPolElt`

```magma
R: Rng                    Default: 
```

Euler factor (=local polynomial) of a Galois representation $A$ over a $p$-adic field $K$. It is defined by

$$
P(T) = \det (1-\mathop{\rm Frob}\nolimits_K^{-1}T|A^{I_K}),
$$

and has degree `Dimension(A)` if and only if $A$ is unramified. The coefficient ring of $P$ (rational/complex/cyclotomic field) may be specified with the optional parameter $R$.

## `Example: Galrep Eulerfactor (ex-641625)`

```magma
> G<chi>:=DirichletGroup(5);
> A:=GaloisRepresentation(chi,2);
> EulerFactor(A);
x + 1
> A:=GaloisRepresentation(chi,5);
> EulerFactor(A);
1

```

## `IsZero(A): GalRep -> BoolElt`

Return `true` if $A$ is the Galois representation $0$.

## `IsOne(A): GalRep -> BoolElt`

Return `true` if $A$ is the trivial $1$-dimensional Galois representation.

## `Factorization(A): GalRep -> List, GalRep`

Returns the list of tuples $\langle\chi_i$,$n_i$,$\rho_i\rangle$, where $A$ is the direct sum over $i$ of twists by ${\tt SP}(n_i)$ by unramified representations with Euler factor $\chi_i$, and a finite Weil representation given by a character $\rho_i$ of `Group(A)`.

## `Example: Galrep Factorization (ex-d8fc15)`

```magma
> R<x>:=PolynomialRing(ComplexField());    // prettier print for complex polys
> K:=pAdicField(2,20);
> S:=SP(K,2);
> S; Factorization(S);
2-dim Galois representation SP(2) over Q2[20]
[*
<-x + 1, 2, ( 1 )>
*]
> A:=Semisimplification(S);
> A; Factorization(A);
2-dim unramified Galois representation Unr(1-3/2*x+1/2*x^2) over Q2[20]
[*
<1/2*x^2 - 3/2*x + 1, 1, ( 1 )>
*]
> [Factorization(I)[1]: I in Decomposition(A)];
[ <-x + 1, 1, ( 1 )>, <-1/2*x + 1, 1, ( 1 )> ]

```

## Ramification

### `InertiaGroup(A): GalRep -> GrpPerm`

For a Galois representation $A$ over a $p$-adic field $K$ this is the image of inertia $I_K\subset\mathop{\rm Gal}\nolimits(\bar K/K)$ under the semisimplification of $A$. Equivalently, if

$$
A = \psi \otimes\hbox{\tt SP}(n) \otimes R,
$$

as in §[Notation and Printing](overview.md#galrep-printing), with $\psi$ unramified and $R$ a representation of a finite Galois group $\mathop{\rm Gal}\nolimits(F/K)$, this is the image of the inertia subgroup of $\mathop{\rm Gal}\nolimits(F/K)$ under $R$. If $F$ is chosen to be minimal possible (so that $R$ is faithful), then `InertiaGroup(A)` simply *is* the inertia subgroup of $\mathop{\rm Gal}\nolimits(F/K)$.

### `Example: Galrep Inertia (ex-e156fa)`

Take $K={\mathbb{Q}}_3$ and $F=K(\zeta_6,\root 6\of 3)$, a $D_6$-extension of $K$. For each of the 6 irreducible representations of $\mathop{\rm Gal}\nolimits(F/K)$ we compute their inertia (=ramification) groups:

```magma
> K:=pAdicField(3,20);
> R<x>:=PolynomialRing(K);
> list:=GaloisRepresentations(x^6-3);
> [GroupName(InertiaGroup(A)): A in list];
[ C1, C2, C1, C2, S3, S3 ]

```

### `InertiaGroup(A, n): GalRep, RngIntElt -> GrpPerm`

The $n$th (lower) ramification subgroup of `InertiaGroup(A)`.

### `Example: Galrep Higherinertia (ex-92ac63)`

```magma
> K:=pAdicField(2,20);
> R<x>:=PolynomialRing(K);
> list:=GaloisRepresentations(x^8-2);
> a:=list[#list]; a;
2-dim Galois representation (2,-2,0,0,0,zeta(8)_8^3+zeta(8)_8,
   -zeta(8)_8^3-zeta(8)_8) with G=SD16, I=SD16, conductor 2^10 over Q2[20]
> [GroupName(InertiaGroup(a,n)): n in [1..17]];
[ SD16, SD16, C8, C8, C4, C4, C4, C4, C2, C2, C2, C2, C2, C2, C2, C2, C1 ]

```

### `IsUnramified(A): GalRep -> BoolElt`

Return `true` if a Galois representation is unramified.

### `Example: Galrep Isunramified (ex-57fb0d)`

```magma
> K:=pAdicField(2,20);
> IsUnramified(CyclotomicCharacter(K));
true
> IsUnramified(SP(K,2));
false
> IsUnramified(Semisimplification(SP(K,2)));
true

```

### `IsRamified(A): GalRep -> BoolElt`

Return `true` if a Galois representation is ramified.

### `Example: Galrep Isramified (ex-27c5ab)`

```magma
> K:=pAdicField(2,20);
> IsRamified(CyclotomicCharacter(K));
false
> IsRamified(SP(K,2));
true
> IsRamified(Semisimplification(SP(K,2)));
false

```

### `IsTamelyRamified(A): GalRep -> BoolElt`

Return `true` if a Galois representation $A$ over a $p$-adic field $K$ is tamely ramified. Equivalently, `InertiaGroup(A)` has order prime to $p$ (and is then automatically cyclic).

### `IsWildlyRamified(A): GalRep -> BoolElt`

Return `true` if a Galois representation $A$ over a $p$-adic field $K$ is wildly ramified, i.e. not tamely ramified. Equivalently, `InertiaGroup(A)` has non-trivial $p$-Sylow.

### `Example: Galrep Iswildlyramified (ex-1ea277)`

Galois representations attached to elliptic curves are always tamely ramified when $p\ge 5$, but may be wildly ramified when $p=2$ or $3$.

```magma
> E:=EllipticCurve("75a1");
> A5:=GaloisRepresentation(E,5); A5;
2-dim Galois representation Unr(sqrt(5)*i)*(2,0,-1) with G=S3, I=C3, conductor
   5^2 over Q5[40]
> IsWildlyRamified(A5);
false
> E:=EllipticCurve("256a1");
> A2:=GaloisRepresentation(E,2); A2;
2-dim Galois representation Unr(sqrt(2))*(2,-2,0,0,0) with G=D4, I=C4,
   conductor 2^8 over Q2[40]
> IsWildlyRamified(A2);
true

```

### `InertiaInvariants(A): GalRep -> GalRep`

Inertia invariants of a Galois representation $A$. This is an unramified Galois representation.

### `Example: Galrep Inertiainvariants (ex-04fb22)`

```magma
> K:=pAdicField(5,20);
> E:=BaseChange(EllipticCurve("15a1"),K);
> A:=GaloisRepresentation(E); A;
2-dim Galois representation Unr(5)*SP(2) over Q5[20]
> I:=InertiaInvariants(A); I;
1-dim trivial Galois representation 1 over Q5[20]
> Dimension(A),Dimension(I);
2 1

```

### `ConductorExponent(A): GalRep -> RngIntElt`

Conductor exponent of a Galois representation.

### `Conductor(A): GalRep -> FldPadElt`

Conductor of a Galois representation.

### `Example: Galrep Conductor (ex-7491ac)`

```magma
> K:=pAdicField(2,40);
> E:=BaseChange(EllipticCurve("256a1"),K);
> A:=GaloisRepresentation(E); A;
2-dim Galois representation Unr(sqrt(2))*(2,-2,0,0,0) with G=D4, I=C4,
   conductor 2^8 over Q2[40]
> ConductorExponent(A);
8
> Conductor(A);
2^8 + O(2^48)
> Conductor(E);    // same, by definition
2^8 + O(2^48)

```

### `EpsilonFactor(A): GalRep -> FldComElt`

Epsilon-factor $\epsilon(A)$ of a Galois representation over a $p$-adic field. Currently only implemented in a few basic cases, and raises an error otherwise. See also Example [Example: Galrep Funeq](fields-2.md#example-ex-938a3a) in §[Example: Local and Global Epsilon Factors for Dirichlet Characters](fields-2.md#galrep-ex1).

### `RootNumber(A): GalRep -> FldComElt`

Root number $\epsilon(A)/|\epsilon(A)|$ of a Galois representation. Currently only implemented in a few basic cases, and raises an error otherwise. See also Example [Example: Galrep Funeq](fields-2.md#example-ex-938a3a) in §[Example: Local and Global Epsilon Factors for Dirichlet Characters](fields-2.md#galrep-ex1).

### `Example: Epsilon Rootnumber (ex-3d8d04)`

```magma
> E:=EllipticCurve("98a1");
> A:=GaloisRepresentation(E,7); A;
2-dim Galois representation Unr(7)*SP(2)*(1,-1) with G=C2, I=C2, conductor 7^2
   over Q7[40]
> RootNumber(A);
-1
> RootNumber(E,7);  // same
-1

```

## Semisimplicity and Irreducibles

### `IsIrreducible(A): GalRep -> BoolElt`

Return `true` if a Galois representation $A$ is irreducible.

### `Example: Galrep Isirreducible (ex-f6575f)`

We take the polynomial $x^8-6$ with Galois group $C_8:C_2^2$ over ${\mathbb{Q}}$, its irreducible 4-dimensional Artin representation $A$, and compute whether its local components over ${\mathbb{Q}}_2$, ${\mathbb{Q}}_3$, ${\mathbb{Q}}_5$ and ${\mathbb{Q}}_7$ are irreducible.

```magma
> R<x>:=PolynomialRing(Rationals());
> K:=NumberField(x^8-6);
> GroupName(GaloisGroup(K));
C8:C2^2
> assert exists(A){A: A in ArtinRepresentations(K) | Degree(A) eq 4};
> A;
Artin representation C8:C2^2: (4,-4,0,0,0,0,0,0,0,0,0) of ext<Q|x^8-6>
> [IsIrreducible(GaloisRepresentation(A,p)): p in PrimesUpTo(10)];
[ true, false, false, false ]

```

### `IsIndecomposable(A): GalRep -> BoolElt`

Return `true` if a Galois representation $A$ is indecomposable (for semisimple representations, i.e. Weil representations, same as irreducible).

### `IsSemisimple(A): GalRep -> BoolElt`

Return `true` if a Galois representation $A$ is semisimple, i.e. a Weil representation.

### `Semisimplification(A): GalRep -> GalRep`

Semisimplification of a Galois representation $A$.

### `Decomposition(A): GalRep -> SeqEnum[GalRep]`

Decompose $A$ into indecomposable (for semisimple representations same as irreducible) consituents and return them as a sequence, possibly with repetitions.

### `Example: Galrep Decomposition (ex-2ab1fc)`

```magma
> K:=pAdicField(2,20);
> S:=SP(K,2);
> IsIndecomposable(S);
true
> IsIrreducible(S);
false
> IsSemisimple(S);
false
> Decomposition(S);
[ 2-dim Galois representation SP(2) over Q2[20] ]
> Decomposition(Semisimplification(S));
[
1-dim trivial Galois representation 1 over Q2[20],
1-dim unramified Galois representation Unr(1/2) over Q2[20]
]

```