# Construction of Subalgebras, Ideals and Quotients

If the coefficient ring $R$ of a Lie algebra $L$ is a Euclidean domain, then submodules and ideals can be constructed in Magma; if $R$ is a field then quotients can be constructed in Magma. Note that left, right, and two-sided ideals are identical in a Lie algebra.

## `sub<L | A>: AlgLie, List -> AlgLie, Map`

## `sub<L | A>: AlgMatLie, List -> AlgMatLie, Map`

Creates the subalgebra $S$ of the Lie algebra $L$ that is generated by the elements defined by $A$, where $A$ is a list of one or more items of the following types:

**(a)**
An element of $L$;

**(b)**
A set or sequence of elements of $L$;

**(c)**
A subalgebra or ideal of $L$;

**(d)**
A set or sequence of subalgebras or ideals of $L$.

As well as the subalgebra $S$ itself, the constructor returns the inclusion homomorphism $f : S \rightarrow L$.

## `ideal<L | A>: AlgLie, List -> AlgLie, Map`

## `ideal<L | A>: AlgMatLie, List -> AlgMatLie, Map`

Creates the ideal $I$ of the Lie algebra $L$ generated by the elements defined by $A$, where $A$ is a list of one or more items of the following types:

**(a)**
An element of $L$;

**(b)**
A set or sequence of elements of $L$;

**(c)**
A subalgebra or ideal of $L$;

**(d)**
A set or sequence of subalgebras or ideals of $L$.

As well as the ideal $I$ itself, the constructor returns the inclusion homomorphism $f : I \rightarrow L$.

## `quo<L | A>: AlgLie, List -> AlgLie, Map`

## `quo<L | A>: AlgMatLie, List -> AlgMatLie, Map`

Forms the quotient algebra $L / I$, where $I$ is the two-sided ideal of $L$ generated by the elements defined by $A$, where $A$ is a list of one or more items of the following types:

**(a)**
An element of $L$;

**(b)**
A set or sequence of elements of $L$;

**(c)**
A subalgebra or ideal of $L$;

**(d)**
A set or sequence of subalgebras or ideals of $L$.

As well as the quotient $L/I$ itself, the constructor returns the natural homomorphism $f : L \rightarrow L/I$.

## `L / S: AlgLie, AlgLie -> AlgLie`

## `L / S: AlgMatLie, AlgMatLie -> AlgLie`

The quotient of the Lie algebra $L$ by the ideal closure of the subalgebra $S$.

## `Example: Lie Algebra Quotient (ex-bb05e7)`

We construct the quotient of the matrix Lie algebra of $2\times 2$ matrices, by the ideal spanned by the identity matrix.

```magma
> L := MatrixLieAlgebra( Rationals(), 2 );
> Dimension(L);
4
> I := ideal< L | L!Matrix([[1,0],[0,1]]) >;
> Dimension(I);
1
> K := L/I;
> Dimension(K);
3
> SemisimpleType( K );
A1

```

## `QuotientWithPullback(L, I): AlgLie, AlgLie -> AlgLie, Map, UserProgram, UserProgram`

Given a Lie algebra $L$ and an ideal $I$ of $L$, this intrinsic returns four values: the quotient $Q = L/I$, the natural homomorphism $\mu : L\to Q$ and two functions, $\sigma$ and $\Sigma$ with domain $Q$. The function $\sigma$ is a section of $\mu$ and also returns the kernel of $\mu$. That is, for $y \in Q$, $\sigma(y)$ returns $x$ and $V$, such that $\sigma(x) = y$ and where $V$ is the underlying vector space of $I$. For $y\in Q$, $\Sigma(y)$ is the subalgebra of $L$ generated by $I$ and $x$.

## `Example: Lie Algebra Quotient Pullback (ex-83d77d)`

We consider an ideal of the Lie algebra of type G$_2$ over the field with $3$ elements.

```magma
> R := RootDatum("G2");
> L := LieAlgebra(R, GF(3));
> pos,neg,cart := StandardBasis(L);
> shrt := [ i : i in [1..NumPosRoots(R)] | IsShortRoot(R, i) ];
> shrt;
[ 1, 3, 4 ]
> I := ideal<L | pos[shrt]>;
> _, str1 := ReductiveType(I); str1;
The 7-dim simple constituent of a Lie algebra of type A2

```

So apparently $I$ is isomorphic to the $7$-dimensional simple constituent of a Lie algebra of type A$_2$. We will now use `QuotientWithPullback` to construct $L/I$.

```magma
> LI, proj, pb, pbsub := QuotientWithPullback(L, I);
> _, str2 := ReductiveType(LI); str2;
The 7-dim simple constituent of a Lie algebra of type A2

```

So apparently $I \simeq L/I$! Finally, we will demonstrate the use of the additional return values. First, we verify that an element of $I$ maps to $0$ in $L/I$:

```magma
> proj(pos[1]);
(0 0 0 0 0 0 0)

```

And then we consider the preimage in $L$ of a randomly chosen element of $L/I$.

```magma
> y := LI![0,1,1,1,1,0,1];
> y;
(0 1 1 1 1 0 1)
> x, V := pb(y);
> x;
(0 1 0 0 1 0 0 1 0 1 0 0 0 1)
> #V;
2187
> assert #V eq #I;
> {* proj(x + v) eq y : v in V *};
{* true^^2187 *}

```

So indeed $x+v$ is a preimage of $y$ for all $v \in V$.

```magma
> M := pbsub(y);
> M, M meet I;
Lie Algebra of dimension 8 with base ring GF(3)
Lie Algebra of dimension 7 with base ring GF(3)
> _,str3 := ReductiveType(M);
> str3;
Twisted Lie algebra of type 2A2 [Ad]

```