Normal Structure and Characteristic Subgroups

Characteristic Subgroups and Subgroup Series

Centre(G): GrpGPC -> GrpGPC

Center(G): GrpGPC -> GrpGPC

The centre of the group \(G\). For nilpotent groups the centre is computed using the centraliser algorithm [Lo, 1998]. Otherwise, it is computed as the simultaneous fixed point space of the action of the generators of \(G\) on the centre of the Fitting subgroup of \(G\) [Eick, 2001].

DerivedLength(G): GrpGPC -> RngIntElt

The derived length of the group \(G\).

DerivedSeries(G): GrpGPC -> [GrpGPC]

The derived series of the group \(G\). The series is returned as a sequence of subgroups.

DerivedSubgroup(G): GrpGPC -> GrpGPC

DerivedGroup(G): GrpGPC -> GrpGPC

The derived subgroup of the group \(G\).

EFASeries(G): GrpGPC -> [GrpGPC]

Returns a normal series of G, the factors of which are either elementary abelian \(p\)-groups or free abelian groups.

FittingLength(G): GrpGPC -> RngIntElt

The Fitting length of the group \(G\), i.e. the smallest integer \(k\) such that \(F_k = G\) where the groups \(F_i\) are defined recursively by \(F_0 := 1\) and \(F_i / F_{i-1} := {\rm Fit}(G / F_{i-1})\) (\(i>0\)). Note that such a \(k\) exists for every polycyclic group \(G\).

FittingSeries(G): GrpGPC -> [GrpGPC]

The Fitting series of the group \(G\), where the groups \(F_i\) are defined recursively by \(F_0 := 1\) and \(F_i / F_{i-1} := {\rm Fit}(G / F_{i-1})\) (\(i>0\)). The series is returned as the sequence \([F_0,\dots,F_k]\) of subgroups of \(G\). Note that every polycyclic group \(G\) has a finite Fitting series ending in \(G\).

FittingSubgroup(G): GrpGPC -> GrpGPC

FittingGroup(G): GrpGPC -> GrpGPC

The Fitting subgroup of the group \(G\), i.e. the maximal nilpotent normal subgroup of \(G\). This function uses an algorithm described in [Eick, 2001].

HasComputableLCS(G): GrpGPC -> BoolElt

This function returns the value true if the lower central series of \(G\) is computable, otherwise it returns the value false. This is useful to avoid runtime errors, when LowerCentralSeries is called in user written loops or functions.

LowerCentralSeries(G): GrpGPC -> [GrpGPC]

The lower central series for the group \(G\). The series is returned as a sequence of subgroups. Since infinite polycyclic groups need not satisfy the descending chain condition for subgroups, computation of the lower central series may fail. To determine if the series can be computed and thereby avoid runtime errors, the function HasComputableLCS may be used. This function uses an algorithm described in [Lo, 1998].

NilpotencyClass(G): GrpGPC -> RngIntElt

The nilpotency class of the group \(G\). If \(G\) is not nilpotent, then \(-1\) is returned.

NilpotentPresentation(G): GrpGPC -> GrpGPC, Map

A polycyclic presentation is called nilpotent, if for all \(i=1,\ldots,n\), \(G_{i+1}\) is normal in \(G\) and \(G_i/G_{i+1}\) is central in \(G/G_{i+1}\). Every nilpotent polycyclic group has a nilpotent polycyclic presentation. A suitable polycyclic series can be obtained by refining the lower central series.

The function NilpotentPresentation computes a group \(N\) isomorphic to \(G\), given by a nilpotent polycyclic presentation and the isomorphism from \(G\) to \(N\).

SemisimpleEFASeries(G): GrpGPC -> [GrpGPC]

Returns a normal series of \(G\), the factors of which are either elementary abelian \(p\)-groups which are semisimple as \({\bf F}_{p}[G]\)-modules or free abelian groups which are semisimple as \({\mathbb{Q}}[G]\)-modules.

The normal series returned by the function SemisimpleEFASeries is a refinement of the normal series returned by the function EFASeries.

UpperCentralSeries(G): GrpGPC -> [GrpGPC]

The upper central series \([Z_0,\dots,Z_k]\) of the group \(G\), where the groups \(Z_k\) are defined recursively by \(Z_0 := 1\) and \(Z_i / Z_{i-1} := {\rm Z}(G / Z_{i-1})\) (\(i>0\)). The series is returned as a sequence of subgroups of \(G\). Note that since polycyclic groups satisfy the ascending chain condition for subgroups, every polycyclic group \(G\) has a finite upper central series.

Example: Normal Structure (ex-c7b9de)

The dihedral group of order 32 is nilpotent; we compute its lower central series.

> D16<a,b> := DihedralGroup(GrpGPC, 16);
> IsNilpotent(D16);
true
> NilpotencyClass(D16);
4
> L := LowerCentralSeries(D16);

Run in calculatorCopy input

The generators of the subgroups in the lower central series expressed as elements of \(D16\) are:

> for i := 1 to 1+NilpotencyClass(D16) do
>   print i, ":", {@ D16!x : x in PCGenerators(L[i]) @};
> end for;
1 : {@ a, b @}
2 : {@ b^2 @}
3 : {@ b^4 @}
4 : {@ b^8 @}
5 : {@ @}

Run in calculatorCopy input

We compute a nilpotent presentation and express the new generators in terms of \(a\) and \(b\):

> N<p,q,r,s,t>, f := NilpotentPresentation(D16);
> N;
GrpGPC : N of order 2^5 on 5 PC-generators
PC-Relations:
    p^2 = Id(N),
    q^2 = r,
    r^2 = s,
    s^2 = t,
    t^2 = Id(N),
    q^p = q * r * s * t,
    r^p = r * s * t,
    s^p = s * t
> {@ x@@f : x in PCGenerators(N) @};
{@ a, b, b^2, b^4, b^8 @}

Run in calculatorCopy input

The infinite dihedral group has an infinite, strictly descending, lower central series which cannot be computed:

> D := DihedralGroup(GrpGPC, 0);
> HasComputableLCS(D);
false

Run in calculatorCopy input

It is easy to see, that \(b^{2^{i-1}}\) would be a generator of \(L_i\).

The symmetric group on 3 letters is not nilpotent, but has a lower central series which becomes stationary and which can be computed:

> F2<a,b> := FreeGroup(2);
> rels := [ a^2 = F2!1, b^3 = F2!1, b^a = b^2 ];
> G<a,b> := quo<GrpGPC : F2 | rels>;
> G;
GrpGPC : G of order 6 = 2 * 3 on 2 PC-generators
PC-Relations:
    a^2 = Id(G),
    b^3 = Id(G),
    b^a = b^2
> IsNilpotent(G);
false
> HasComputableLCS(G);
true
> L := LowerCentralSeries(G);
> for i := 1 to #L do
>   print i, ":", {@ G!x : x in PCGenerators(L[i]) @};
> end for;
1 : {@ a, b @}
2 : {@ b @}

Run in calculatorCopy input

The Abelian Quotient Structure of a Group

AbelianQuotient(G): GrpGPC -> GrpAb, Map

The maximal abelian quotient \(G/G^\prime\) of the group \(G\) as GrpAb (cf. Chapter Abelian Groups). The natural epimorphism is returned as second return value.

AbelianQuotientInvariants(G): GrpGPC -> [ RngIntElt ]

AQInvariants(G): GrpGPC -> [ RngIntElt ]

Returns a sequence containing the invariants of the maximal abelian quotient \(G/G^\prime\) of the group \(G\). Each infinite cyclic factor of \(G/G^\prime\) is represented by zero.

ElementaryAbelianQuotient(G, p): GrpGPC, RngIntElt -> GrpAb, Map

The maximal \(p\)-elementary abelian quotient of the group \(G\) as GrpAb (cf. Chapter Abelian Groups). The natural epimorphism is returned as second return value.

FreeAbelianQuotient(G): GrpGPC -> GrpAb, Map

The maximal free abelian quotient of the group \(G\) as GrpAb (cf. Chapter Abelian Groups). The natural epimorphism is returned as second return value.