Operations on Elements#

Equality and Comparison#

u eq v: GrpBBElt, GrpBBElt -> BoolElt#: Returns true if and only if the underlying concrete group elements for \(u\) and \(v\) are equal.

u ne v: GrpBBElt, GrpBBElt -> BoolElt#: Returns true if and only if the underlying concrete group elements for \(u\) and \(v\) are not equal.

Attributes of Elements#

Parent(u): GrpBBElt -> GrpBB#: The parent group \(G\) of the element \(u\).

UnderlyingElement(u): GrpBBElt -> GrpElt#: The concrete group element corresponding to the BB-group element \(u\).

Order(u): GrpBBElt -> RngIntElt#: The order of the underlying concrete group element of \(u\).

Example: Standard Gens (ex-124120)#

The following function takes a black box group isomorphic to \(M_{24}\) and finds standard generators. It is taken from the ATLAS of Finite Group Representations page on \(M_{24}\).

> m24_standard := function(B)
> repeat a := PseudoRandom(B); until Order(a) eq 10;
> a := a ^ 5;
> repeat b := PseudoRandom(B); until Order(b) eq 15;
> b := b ^ 5;
> repeat b := b ^ PseudoRandom(B); ab := a*b;
> until Order(ab) eq 23;
> x := ab*(ab^2*b)^2*ab*b;
> if Order(x) eq 5 then b := b^-1; end if;
> return a,b;
> end function;

Run in calculator

We take a group which must be \(M_{24}\) and find these generators.

> G := PermutationGroup<24 |
> [ 20, 4, 10, 3, 15, 9, 7, 1, 11, 22, 21, 19, 8, 2, 24, 5,
> 12, 18, 13, 16, 14, 23, 6, 17 ],
> [ 12, 18, 3, 2, 7, 11, 5, 21, 19, 22, 23, 1, 14, 17, 10,
> 8, 4, 13, 24, 20, 9, 15, 6, 16 ]>;
> #G;
244823040
> Transitivity(G);
5
> B := NaturalBlackBoxGroup(G);
> a,b := m24_standard(B); a,b;
GrpBBElt (1, 16)(2, 22)(3, 14)(4, 15)(5, 11)(6, 24)(7,
10)(8, 18)(9, 19)(12, 17)(13, 20)(21, 23)
GrpBBElt (1, 14, 17)(2, 18, 13)(5, 16, 20)(7, 22, 9)(8, 24,
15)(19, 23, 21)

Run in calculator

The printing of the GrpBBElts shows the underlying concrete group elements. These may be extracted using the UnderlyingElement intrinsic for use within \(G\).