Vector and Spin Representations

Throughout this section, let \(Q\) be a quadratic form of Witt index \(r\) on a vector space \(V\) over a finite field \(F\) such that the polar form of \(Q\) is non-degenerate and let \(C\) denote the Clifford algebra of \(Q\).

The Clifford Group

The Clifford group of \(C\) is

\[\Gamma = \{\, s \in C \mid s\text{ is a unit and }s^{-1}vs \in V\text{ for all }v\in V\,\}\]

and the vector representation of \(\Gamma\) is the homomorphism \(\chi : \Gamma \to {\operatorname{GL}}(V)\) such that for \(s\in \Gamma\), \(\chi(s)\) is the linear transformation sending \(v\in V\) to \(s^{-1}vs\). In fact, \(\chi(\Gamma)\) is a subgroup of the orthogonal group \(O(V,Q)\). Except when the Witt index of \(Q\) is 2 and \(V\) is a space of dimension 4 over \({\bf F}_{2}\), if \(\dim V\) is even, \(\chi(\Gamma) = O(V,Q)\) and if \(\dim V\) is odd, \(\chi(\Gamma) = {\operatorname{SO}}(V,Q)\). (See [Che97] for further details.)

VectorAction(g): AlgClffElt -> AlgMatElt

The matrix of the Clifford group element \(g\in \Gamma\) acting on the quadratic space \(V\) by conjugation.

Example: Reflections from the Clifford Group (ex-6e1ea1)

Run in calculator (opens in a new tab)

If \(v\) is a non-singular element of \(V\), the negative of the linear transformation \(\chi(v)\) is the reflection in the hyperplane orthogonal to \(v\).

> F := GF(3);
> Q := StandardQuadraticForm(6,F);
> C, V, f := CliffordAlgebra(Q);
> v := V![2,0,2,0,0,1];

In order to ensure \(v\) is non-singular we check its quadratic norm.

> QuadraticNorm(v);
2
> A := VectorAction(f(v));
> -A eq OrthogonalReflection(v);
true

Run in calculator (opens in a new tab)

Siegel Transformations and Spin Groups

The special Clifford group is \(\Gamma^+ = \Gamma\cap C_+\) and \(\chi(\Gamma^+) = {\operatorname{SO}}(V,Q)\). If \(\alpha\) is the main anti-automorphism of \(C\), the spin group of \(Q\) is

\[{\operatorname{Spin}}(V,Q) = \{\,s\in \Gamma^+ \mid \alpha(s)s = 1\,\}.\]

Given the polar form \(\beta\) of \(Q\) and linearly independent vectors \(u,v \in V\) such that \(u\) is singular and \(\beta(u,v) = 0\), the Siegel transformation defined by \(u\) and \(v\) (see Chapter Polar Spaces) is the isometry \(\rho_{u,v}\) defined by

\[x \rho_{u,v} = x + \beta(x,v)u - \beta(x,u)v - Q(v)\beta(x,u) u.\]

In the Clifford algebra of \(Q\), the conditions on \(u\) and \(v\) become \(u^2 = 0\) and \(uv + vu = 0\). Thus \(uv - 1\in {\operatorname{Spin}}(V,Q)\) and \(\chi(uv-1) = \rho_{u,v}\). Except for \(\Omega^+(4,2)\) the group \(\Omega(V,Q)\) is generated by Siegel transformations and thus \(\chi :{\operatorname{Spin}}(V,Q) \to \Omega(V,Q)\) is onto; its kernel is \(\{\pm 1\}\).

Example: Siegel Transformations (ex-c93d8c)

We verify that a Siegel transformation \(\rho_{u,v}\) can be obtained as the vector representation of \(uv-1\).

> F := GF(3);
> Q := StandardQuadraticForm(6,F);
> C, V, f := CliffordAlgebra(Q);
> u := V.1;
> v := V.5;
> VectorAction(f(u)*f(v) - One(C)) eq SiegelTransformation(u,v);
true

Run in calculator (opens in a new tab)

Regarding \(\Omega(V,Q)\) as a group of Lie type, the subgroups \(X_{u,v} = \langle\, \rho_{tu,v} \mid t \in F \,\rangle\) are root groups. (If \(\dim V = 2r\), we consider only the groups for which both \(u\) and \(v\) are singular.) In Magma, the generators of the groups \(\Omega(V,Q)\) are defined in terms of root elements (see [RT98]).

Example: Spin Preimages of Standard Generators (ex-1c9644)

Run in calculator (opens in a new tab)

When \(F = {\bf F}_{q}\) and \(\dim V = 2r\) we construct the elements of \({\operatorname{Spin}}(V,Q)\) which map onto the standard generators of \(\Omega^+(2r,q)\).

> q := 3;
> r := 4;
> K := GF(3);
> Q := StandardQuadraticForm(2*r,K);
> C,V,f := CliffordAlgebra(Q);

The root element \(x_{\alpha_k}(t)\) indexed by the \(k\)th simple root is given by the following function.

> x := func< k,t |
>   k eq 1 select VectorAction(f(t*V.(r+2))*f(V.(r+1))-One(C))
>   else VectorAction(f(t*V.(r-k+2))*f(V.(r+k))-One(C)) >;

It turns out that our choice of \(Q\) ensures that the matrices of the negative root elements are the transposed matrices of the corresponding positive roots.

> n := func< k, t | x(k,t)*Transpose(x(k,-t^-1))*x(k,t) >;
> h := func< k, t | n(k,t)*n(k,-1) >;
> w := n(1,1)*n(2,1)*n(3,1)*n(4,1);
> xi := PrimitiveElement(K);
> G := OmegaPlus(2*r,q);
> G.1 eq h(2,xi);
true
> G.2 eq Transpose(x(1,1))*x(3,1)*w;
true

Note that the vector representation of \({\operatorname{Spin}}(V,Q)\) is not faithful.

> VectorAction(-One(C)) eq IdentityMatrix(K,2*r);
true

Run in calculator (opens in a new tab)

Spin Representations

If the dimension of \(V\) is \(2r\), the Clifford algebra \(C\) of \(Q\) is simple and hence all irreducible representations are equivalent. We may take the representation space to be a minimal right ideal \(S\) of \(C\). The elements of \(S\) are spinors and the representation itself is the spin representation. The restrictions of this representation to the groups \(\Gamma\), \(\Gamma^+\), and \(\Spin(V,Q)\) are also called spin representations. The spin representation of \(\Gamma\) is irreducible except when the field has order 2, \(r = 1\) and the Witt index is 1.

ActionMatrix(S, s): AlgAss, AlgAssElt -> AlgMatElt

The matrix representing the action of \(s\) on the right ideal \(S\) of an associative algebra \(A\) and \(s\) is an element of \(A\).

Example: Minimal Right Ideals of the Even Subalgebra (ex-b3def3)
> F := GF(5);
> Q := StandardQuadraticForm(4,F);
> C,V,f := CliffordAlgebra(Q);
> E, h := EvenSubalgebra(C);
> IsSimple(E);
false
> S := MinimalRightIdeals(E)[1];
> s := (f(V.1+V.4)*f(V.2+V.3))@@h;
> ActionMatrix(S,s);
[0 4]
[1 0]

Run in calculator (opens in a new tab)

Example: Constructing a Spin Representation (ex-d57a8d)

Run in calculator (opens in a new tab)

The Magma functions Spin, SpinPlus, and SpinMinus construct the groups using highest weight representations of the corresponding group of Lie type. But in this example we construct the spin representation of \(\Spin^+(8,3)\) by working directly with the Clifford algebra.

> q := 3;
> r := 4;
> K := GF(3);
> Q := StandardQuadraticForm(2*r,K);
> C,V,f := CliffordAlgebra(Q);

We adapt the code from Example Spin Preimages of Standard Generators.

The root element \(x_{\alpha_k}(t)\) indexed by the \(k\)th simple root is given by the Magma function x(k,t) and the corresponding negative root element is y(k,t).

> x := func< k,t |
>   k eq 1 select f(t*V.(r+2))*f(V.(r+1))-One(C)
>   else f(t*V.(r-k+2))*f(V.(r+k))-One(C) >;
> y := func< k,t |
>   k eq 1 select f(t*V.r)*f(V.(r-1))-One(C)
>   else f(t*V.(r-k+1))*f(V.(r+k-1))-One(C) >;

The other functions are the same as before.

> n := func< k, t | x(k,t)*y(k,-t^-1)*x(k,t) >;
> h := func< k, t | n(k,t)*n(k,-1) >;
> w := n(1,1)*n(2,1)*n(3,1)*n(4,1);

The spin representation space is a minimal right ideal of the Clifford algebra.

> S := MinimalRightIdeals(C : Limit := 1)[1];
> Dimension(S);
16
> X := sub<GL(16,K) | ActionMatrix(S,h(2,2)), ActionMatrix(S,y(1,1)*x(3,1)*w) >;
> LieType(X,3);
true <"D", 4, 3>
> LMGOrder(X);
19808719257600
> Z := LMGCentre(X);
> #Z, IsElementaryAbelian(Z);
4 true
> SS := SpinPlus(8,K);
> #SS;
19808719257600

The spin representation of \({\operatorname{Spin}}^+(8,3)\) is the direct sum of two half spin representations, neither of which is faithful. The half spin spaces are minimal ideals of the even subalgebra of \(C\).

> E, phi := EvenSubalgebra(C);
> T := MinimalRightIdeals(E : Limit := 1)[1];
> Dimension(T);
8
> Y := sub<GL(8,K) | ActionMatrix(T,h(2,2)@@phi),
>                    ActionMatrix(T,(y(1,1)*x(3,1)*w)@@phi) >;
> LieType(Y,3);
true <"D", 4, 3>
> LMGOrder(Y);
9904359628800

Run in calculator (opens in a new tab)